CommuniGate Pro: CommuniGate Programming Language (CG/PL)

下記は、簡単なCG/PL プログラムの例です。

//	
// A simple CG/PL application
//
entry Main is
  myName = "Jim" + " " + "Smith";
  if length(myName) > 10 then
    myName = Substring(myName,0,8) + "..";
  end if;
end;

CG/PL では、データをオブジェクトとして扱います。オブジェクトの種類としては、文字列、 a 数値、 a データブロック、 a タイムスタンプ、 an IP アドレス、 an 配列、 or a 辞書が. 詳しくは「データ」のセクションを参照してください。

上記のオブジェクトのほか、メールボックスハンドル や タスクハンドルなど、特定の環境内で定義された特殊オブジェクトも使用できます。

特殊なタイプのオブジェクトとしてNULL 値（オブジェクトがない値）があります。

論理（ブール）値の処理では、NULL 値を偽（FALSE）、文字列を真（TRUE）として使用します。

プログラムソースコードはプレーンテキストで、　UTF-8 キャラクタセットを使ってエンコードされます。

CG/PL の語彙は次の通りです。

keywords - and, elif, else, entry, exitif, external, false, forward, function, if, is, not, loop, null, or, procedure, return, spawn, stop, then, true, xor, while.
キーワードはいずれも、大文字と小文字は区別されません。

名前－アルファ記号で始まる文字列で、その後にアルファ記号、数字、下線を付加できます。
名前はいずれも、大文字と小文字は区別されません。
キーワードを名前として使用することはできません。

数値（ナンバー）－ひとつながりの数字。

文字列 - －引用符付きの文字列。詳しくは、「データ」のセクションを参照。
符号 - +, -, *, //, /, %, =, ==, !=, <, <=, >, >=, !, &, &&, |, ||, ?, ;, ,, :, (, ), [, ], {, }

コメントとは、ダブルスラッシュ（//）で始まり、それ以後のEOL （行の終り）まで（EOL を含む）の文字列をいいます。

ホワイトスペースとは、スペース、タブ、EOL、コメント文字（いずれも1 個以上）をいいます。名前とキーワードの間には、少なくても一つホワイトスペースを挿入しなければなりません。名前とキーワード以外の語彙素は、0 個以上のホワイトスペースで区切ることができます。

プロシージャ名または関数名として宣言されていない名前、また、内蔵のプロシージャ名または関数名でない名前はいずれも変数名として使用できます。

各変数には値を割り当てることができます。変数の値は、最初はNULL 値です。変数にはオブジェクトを割り当てることができ、割り当てた場合、そのオブジェクトが変数の値になります。

myCount = 3;           // 変数myCount を作成し
                       // 値として数値3 を割り当てる
myCount = myCount + 2; // 変数myCount の値を5 に変更
myCount = "Service";   // 変数myCount の値を文字列に変更

変数は、生成された関数/ プロシージャインスタンスに対してローカルです。また、関数/ プロシージャが終了する（返る）と、変数の値はすべて削除されます。

CG/PL では単項演算がサポートされています。単項演算の形式は次の通りです。

operation operand （演算子オペランド）

次の単項演算が可能です。

-: 単項マイナス。オペランドの値が数値の場合、演算結果は、その数値の符号の反対の符号が付いた数値になります。数値でない場合、演算結果は0 となります。　　　　　
下記の式の値は-5 です。
-5
-(3+2)
+: 単項プラス。オペランドの値が数値の場合、演算結果は、その数値です。数値でない場合、演算結果は0 となります。
下記の式の値は5 です。
+5
+(10/2)
not: 否定。オペランドの値がNULL 値の場合、演算結果はTRUE、そうでない場合はNULL 値となります。
キーワードnot の代わり符号! を使っても処理は同じです。
次のどちらの式も、値は"YES"（TRUE）です。
not null
!(2 == 3)

単項演算の優先度は、二項演算と三項演算より上です。したがって、下記の式の結果は-3 ではなく -1 です。

-2 + 1

CG/PL では、二項演算をサポートしています。二項演算は、次の形式で指定します。

left-operand operation right-operand （左オペランド演算子右オペランド）

特に指定しない限り、両側のオペランドが計算され（順番は不定）、その結果に対して演算が実行されます。

二項演算の演算子としては次の演算子がサポートされています。優先度は降順（高から低）です。

*, /, %

上の演算子はいずれも、数値のオペランドに対してのみ使用が可能です。
オペランドのいずれかが数値でなかったとき、または、演算子が/ または% で右オペランドが0 だった場合、演算結果はNULL 値となります。
下記の式の結果はいずれも10 です。

5 * 2
-20 / -2
30 % 20

+, -

この2 つの演算子はどちらも、数値のオペランドに対してのみ使用が可能です。
+ 演算子は、2 つの文字列オペランドに対して使用できます。結果は、2 つの文字列が連結された文字列です。
また、+ 演算子は、2 つのデータブロックオペランドに対して使用できます。結果は、2 つのデータブロックが連結されたデータブロックです。
さらに、+ 演算子は、タイムスタンプと数値をそれぞれオペランドとして使用できます。結果は、タイムスタンプに数値（秒）を加えた値です。
- 演算子は、左オペランドにタイムスタンプを指定し、右オペランドに数値を指定して演算が可能です。結果は、タイムスタンプから数値（秒）を差し引いた値です。
The - operation can be applied to a pair or operands with timestamp values, producing a numeric value - the number of seconds between the left and the right operand values.
上記以外の場合、結果はNULL 値です。
次の式の結果は5 です。

3 + 2
-2 - -7

次の式の結果は"John Doe" です。

"Joh" + "n Doe"

<, <=, ==, !=, >=, >

いずれも比較演算子で、数値オペレンドに対して実行が可能です。算術比較条件が満足された場合、TRUE が返ります。
== と != は、2 つの数値のほか、2 つのオブジェクトについて使用し、その2 つのオブジェクトが「等しい」かどうかチェックできます。== と!= では、次のような比較が可能です。　

NULL 値とNULL 値との比較で、両方ともNULL 値かどうか。
数値と数値の比較で、その値が同じかどうか。
文字列と文字列の比較で、その長さと文字列上の各文字の位置が同じかどうか。
データブロックとデータブロックの比較で、その長さとブロック上の各データバイトの位置が同じかどうか。
タイムスタンプとタイムスタンプの比較で、その秒データが等しいかどうか。
配列と配列の比較で、その要素の数と要素の位置が同じかどうか。
辞書と辞書の比較で、キーと値の数、キー（文字列）、キーの値がすべて同じかどうか。
上記以外のオブジェクトの場合、2 つのオブジェクトが同じかどうか（オブジェクトの種類が異なるときには、同じとは判断されません）。

比較条件が満足されなかった場合、結果はNULL 値です。
次のいずれの式も、結果は"YES"（TRUE）です。

1+2 == 3
2+2 != 3
2+2 >= 3
"Joe" == "Joe"
null == (2 == 3)

and, or, xor, and then, or else

1+2 == 3 & 2+2 == 4
2+2 == 3 or else 7-5 == 2
false ^ true

二項演算では、演算の優先度が同じ場合、左から右に計算されます。例えば、 X op Y op Z は ( X op Y ) op Z と同じです。　

二項演算の優先度は、三項演算より上です。

CG/PL では、三項演算としては次の形式だけをサポートしています。

cond ? expr1 : expr2

まず、最初のcond （条件）が計算されます。
その値がNULL 値でなかった場合、次にexpr1 が計算され、その値が結果となります。
cond がNULL 値だったときには、expr2 が計算され、その値が結果になります。

次の式の結果は、どちらも"Good" です。

3 == 3 ? "Good" : "Bad"
null ? 77777 : "Good"

三項演算は、右から左へと計算されます。例えば、 A ? B : C ? D : E は、 A ? B : (C ? D : E) と同じです。

CG/PL では、インデキシング処理（インデックスの参照と値の処理）がサポートされています。

object[index]

上で、: 式objectの値は、配列か辞書でなければなりません（そうでない場合、プログラム例外が発生します）。; 式indexの値は数値で、かつobjectの要素の数より小さい数値でなければなりません。

式objectの値が配列の場合、配列の要素のインデックス（開始値は0、つまり最初の要素のインデックスが0）が参照されます。
インデックスの参照を介して配列の要素の取り出しが行われ、その要素が存在しなかった場合、 NULL 値が返ります。
存在しない最初の要素（存在する最後の要素の次の要素）を指定し、その要素に新規の値を割り当てることができます（下記の例を参照）。
上記以外の要素（存在する最後の要素の次の要素より後の要素）を指定し、新規の値を割り当てた場合、プログラム例外が発生します。
例えば、下記の配列SquareArray の内容が(1,4,9,16,25) の場合、次の式の値は9 です。

SquareArray[2]

また、次の式では、

SquareArray[5] = "Blue";

配列SquareArray の内容は(1,4,9,16,25,"Blue") に変更されます（存在する最後の要素の次の要素に新規の値が割り当てられます）。

式objectの値が辞書の場合、処理では、辞書のキーのインデックス（開始値は0、つまり最初のキーのインデックスが0）が参照されます。
インデックスの参照を介してキーの名前の取り出しが行われます。その要素が存在しなかった場合、 NULL 値が返ります。
参照先のキーに新規の値を割り当てることはできません。その処理を行うと、プログラム例外が発生します。

例えば、下記の辞書SquareDictionary の内容が{"one" = 1; "two" = "four"; "three"=9;} の場合、次の式の値は"three" です。

SquareDictionary[2]

If the object expression value is a string, the operation returns a 1-byte string containing the string symbol number index (the first string symbol has the number 0).
Retrieving a symbol that does not exist results in a null-value.
An attempt to assign a new value to any string symbol results in a program exception.
If SquareString value is "grass", the following expression has the value of "r":

SquareString[1]

またCG/PL では、次の書式を使って辞書の要素の値（キーの値）を取り出すことができます。

dictionary.keyName

上で、: 式dictionaryは、辞書でなければなりません（そうでない場合、プログラム例外が発生します）; keyName は、辞書のキーの名前です。

処理では、辞書dictionary の要素のうち、keyNameで示されるキーの値が取り出されます。
指定したキーが存在しなかった場合、NULL 値が返ります。
キーにNULL 値を割り当てると、そのキーと値の対が辞書から削除されます。
存在しないキーに非NULL 値を割り当てることができます。その場合、新規のキーと値（指定した非NULL 値）の対が辞書に追加されます。
例えば、辞書SquareDictionary の値が{"one" = 1; "two" = "four"; "three"=9;} の場合、
次の式の値は9 です。

SquareDictionary.three

また、次の式ではnull 値が返ります。

SquareDictionary.four

CG/PL では、次の書式を使ってキーを計算し、その値を取り出すことができます。

dictionary.(keyExpr)

上で、: 式dictionaryは、辞書でなければなりません。; また、式keyExpr は、辞書のキーを示す文字列でなければなりません（そうでない場合、プログラム例外が発生します）

処理では、辞書dictionaryのキーkeyExpr の値が取り出されます。
例えば、辞書SquareDictionary の内容が{"one" = 1; "two" = "four"; "three"=9;} の場合、次の式の値は9 となります。

SquareDictionary.("th" + "ree")

さらにCG/PL では、関数呼び出しが可能です。関数呼び出しでは、関数名の後に複数の式をカッコで囲んで指定（パラメータ式）することができます。
なお、関数名は、内蔵関数または定義済み関数の名前でなければなりません。処理の際、パラメータ式（指定した場合）が計算され、そのパラメータの値を使って関数コードが実行されます。関数の実行後、オブジェクトが返ります。関数の結果に対して、インデキシング処理などの辞書の要素に関する処理を実行することもできます。

例えば、パラメータが2 つの関数MyFunction の戻り値が配列(1,"four",9) の場合、次の式では、値として"four" （インデックスが1 の要素の値）が出力されます。

MyFunction(1,"zzz")[1]

式では、キーワードnull またはfalse を使ってfalse 値を指定できます。また、キーワード true を使ってtrue 値を指定できます。

0 個以上の演算子のつながりを演算子シーケンスと呼んでいます。シーケンスの末尾にはセミコロン（;）を置きます。

下は空のシーケンス（演算子なし）で、処理は何も実行されません。

;

また、null 演算子（キーワードnull）を使用したシーケンスも処理は何も実行されません。.

null;

データコンテナ参照（変数、配列の要素、辞書の要素）、　= 記号、式（この式が計算され、その結果がデータコンテナに割り当てられます）の組み合わせを割り当て演算子と呼びます。

myVar = 123 + 111;
myVar = "string";

データコンテナ参照が配列の要素の場合、その要素は、実際に存在する要素、または存在しない最初の要素（存在する最後の要素の次の要素）でなければなりません。つまり、要素が3 つの配列の場合、インデックスが0、1、2 のいずれか、またはインデックスが3 の要素に限って値を割り当てることができます。インデックスが3 の要素に値を割り当てた場合、配列に新規の要素が自動的に追加されます。

データコンテナ参照が辞書の要素の場合、要素にNULL 値を割り当てると、その要素が辞書から削除されます。

プロシージャ呼び出し演算子を使ってプロシージャを呼び出すことができます。書式は、関数呼び出し式と同じです。プロシージャの名前は、内蔵プロシージャまたは定義済みプロシージャの名前でなければなりません。

例えば、パラメータが2 つのプロシージャMyProc は、次のようにして呼び出すことができます。

MyProc(1,"zzz");

タスクは、ストップ演算子を使って終了できます。この場合、キーワードstop を使用します。

stop;

アクティブの接続に対してストップ演算子を使用すると、その接続が閉じます。リターン演算子を使って、関数またはプロシージャの実行を終了させることができます。
リターン演算子は関数の中で使用でき、書式はキーワードreturn と式の組み合わせです。この式が計算され、その値が関数呼び出しの値となります。

return 12*year+month;

また、リターン演算子は、プロシージャの中でも使用できます。その場合、下記のようにキーワード return だけを使用します。

return;

条件演算子は、キーワードif とその右の式（if 式）、演算子シーケンス（if シーケンス）、キーワードend で構成されます。キーワードend にはオプションでキーワードif を付加することもできます。まず、if 式が計算され、その値がNULL 値でなかった場合、if シーケンスが実行されます。その後、条件演算が終了します。

次の例では、変数myCount の値が10 より小さい場合、変数myCount の値が2 だけ増加します。

if myCount < 10 then
myCount = myCount + 2;
end if;

条件演算子では、オプションでif シーケンスの後に単一もしくは複数のelif 部を指定できます。elif 部は、キーワードelif、式（elif 式）、キーワードthen、演算子シーケンス（elif シーケンス）で構成されます。
if 式の値がNULL 値の場合、最初のelif 式が計算され、最初のelif 式の値がNULL 値でなかったときには、そのelif シーケンスが実行され、条件演算が終了します。一方、最初のelif 式の値がNULL 値だった場合、次のelif 部が処理されます。
次の例では、変数myCount の値がチェックされます。その値が10 より小さかったときには、変数の値が2 だけ増加されます。そうでなく（変数myCount の値が10 以上で）、かつ変数myCount の値が 20 より小さかった場合、その値が3 だけ減少されます。

if myCount < 10 then
myCount = myCount + 2;
elif myCount < 20 then
myCount = myCount - 3;
end if;

条件演算子にはまた、else 部を指定することもできます。このelse 部は、if シーケンスの後、また elif 部があるときには、その最後に指定します。else 部は、キーワードelse と演算子シーケンス（else シーケンス）で構成されます。
if 式の値がNULL 値で、オプションのelif 式の値がいずれもNULL 値の場合、else シーケンスが実行され、条件演算が終了します。
次の例では、変数myCount の値が10 より小さかった場合、その値が2 だけ増えます。また、値が 10 以上でかつ20 未満だったときには、その値は3 だけ減ります。一方、これ以外の場合、値が4 倍されます。

if myCount < 10 then
  myCount = myCount + 2;
elif myCount < 20 then
  myCount = myCount - 3;
else
  myCount = myCount * 4;
end if;

ループ演算子とは、キーワードループ演算子とは、キーワードloop を使った演算子をいいます。キーワードloop の前にはオプションでキーワードwhile と式（while 式）を付加できます。また、演算子シーケンス（初期シーケンス）があり、最後にキーワードend （オプション、キーワードloop の前に置きます）が来ます。を使った演算子をいいます。キーワードloop の前にはオプションでキーワードwhile と式（while 式）を付加できます。また、演算子シーケンス（初期シーケンス）があり、最後にキーワードend （オプション、キーワードloop の前に置きます）が来ます。
while 式を指定した場合、その式が計算され、その値がNULL 値だったときにはループ演算子の処理が終了します。そうでない場合、演算子シーケンスが実行されます。この処理が繰り返されます。

次の例では、変数myCount の値がチェックされ、その値が10 より小さい間、値が2 だけ増加されます。

while myCount < 10 loop
myCount = myCount + 2;
end loop;

次の例では、ループ（条件なし）の中でプロシージャmyProc を呼び出しています。

loop
myProc(2,"test.wav");
end loop;

ループ演算子では、演算子シーケンス（初期シーケンス）とキーワードend の間に単一もしくは複数のexitif 部を挿入できます。exitif 部は、キーワードexitif、その後に式（exitif 式）、セミコロン（;）、演算子シーケンス（exitif シーケンス）という書式で指定します。処理の際には、まず初期シーケンスが実行され、その後、最初のexitif 式が計算されます。そのexitif 式の値がNULL 値でなければ、ループ演算子の処理は終了します。そうでない場合、exitif シーケンスが実行され、さらに次の exitif 式（ある場合）が計算されます。最後のexitif シーケンスの実行後、ループ演算子の処理が繰り返されます。

次の例では、変数myWord に文字列"aaa" が追加され、その後、変数の長さがチェックされます。ここで長さが20 より小さかった場合、変数myWord に文字列"bbb" が追加され、処理が反復されます。

loop
myWord = myWord + "aaa";
exitif length(myWord) >= 20;
myWord = myWord + "bbb";
end loop;

代替フォーム

シーケンスの中の演算子によっては、代替フォームを使用できるもの（例えば、then の代わりに{）もあります。代替フォームの後にはセミコロンを付加する必要はありません。

条件演算子の代替フォームは、キーワードif と、式（if 式）、演算子シーケンス（if シーケンス）で構成されます。このうちif シーケンスは、左側と右側をそれぞれ左中カッコ（{）と右中カッコ（}）で囲みます。
条件演算子の代替フォームでは、if シーケンスの後に単一もしくは複数のelif 部を指定できます。elif 部はいずれも、キーワードelif、式（elif 式）、演算子シーケンス（elif シーケンス）で構成されます。elif シーケンスもif シーケンスと同じく、左中カッコ（{）と右中カッコ（}）で囲みます。
また、条件演算子の代替フォームでは、else 部を指定することもできます。else 部は、中カッコで囲まれたif シーケンスの後、かつ、オプションのelif 部の最後に置かなければなりません。else 部は、キーワードelse、式（else 式）、演算子シーケンス（else シーケンス）で構成されます。else シーケンスもif シーケンスと同じく、左中カッコ（{）と右中カッコ（}）で囲みます。

次の例では、変数myCount の値が10 より小さかった場合、その値が2 だけ増えます。また、値が 10 以上でかつ20 未満だったときには、その値は3 だけ減ります。これ以外の場合、値が4 倍されます。

if (myCount < 10) {
  myCount = myCount + 2;
} elif (myCount < 20) {
  myCount = myCount - 3;
} else {
  myCount = myCount * 4;
}

注意: 上の例では、if 式とelif 式は丸カッコで囲まれていますが、必ずしも丸カッコで囲む必要はありません。

ループ演算子の代替フォームは、キーワードwhile、式（while 式）、左側中カッコ（{）、演算子シーケンス（初期シーケンス）、0 個以上のexitif 部、右側中カッコ（}）で構成されます。
exitif 部はそれぞれ、キーワードexitif、式（exitif 式）、セミコロン（;）、演算子シーケンスで構成されます。

次の例では、変数myWord に文字列"aaa" が追加され、その後、変数の長さがチェックされます。ここで長さが20 より小さかった場合、変数myWord に文字列"bbb" が追加され、処理が反復されます。

while ( true ) {
myWord = myWord + "aaa";
exitif (length(myWord) >= 20);
myWord = myWord + "bbb";
}

注意: 上の例では、while 式とexitif 式は丸カッコで囲まれていますが、必ずしも丸カッコで囲む必要はありません。

プログラムコードは、複数のコードセクションで構成されます。コードセクションとしては次の種類があります。

エントリコードセクション。このコードセクションは、プログラムの起動時に実行されます。
プロシージャコードセクションと関数コードセクション。どちらも、エントリコードセクションまたは別のプロシージャコードセクション、関数コードセクションの中に置くことができます（その場所から、プロシージャや関数を呼び出せます）。

プロシージャ/ 関数は、再帰的に呼び出すことができます。つまり、プロシージャまたは関数から直接、または別のプロシージャ/ 関数の呼び出しを介して、そのプロシージャまたは関数自体を呼び出すことができます。

コードセクションはいずれも「再入可能」です。つまり、同一のコードセクションを同時に複数のプログラムで使用（起動またはタスク経由）できます。

コードセクションを使用する場合、宣言が必要です。宣言としては、前方宣言、外部宣言、定義（コードセクション自体の定義）を使用できます。

同一のコードセクションの外部宣言または定義（本体）は、同一のプログラムコードには一つ（どちらか一方のみ一つ）しか指定できません。また、同一のコードセクションの前方宣言は、同一のプログラムコードには一つしか指定できません。その前方宣言の後に定義を指定します。
2 つ（またはそれ以上）のコードセクションで呼び出しを相互に実行させたい場合、前方定義を使います。この方法により、コードセクションが他方のコードセクションで呼び出されるようになります。

外部宣言を使うことで、別のプログラムコードモジュールに定義されているコードセクションを呼び出すことができます。
外部宣言は、外部宣言がサポートされている環境（例えばリアルタイムアプリケーション環境など）でのみ使用が可能です。詳しくは、後述の環境の説明を参照してください。
外部宣言に指定されているコードセクションの名前とパラメータ名は、外部プログラムコードモジュールに定義されているコードセクションの名前とパラメータ名と同じでなければなりません。
コードセクション定義の中のパラメータは、外部宣言のパラメータより多くてもかまいません。外部宣言にないパラメータには、外部宣言の処理時に自動的にNULL 値が割り当てられます。

エントリ

エントリの宣言（エントリコードセクションの宣言）は、キーワードentry とエントリ名のほか、次の要素で構成されます（宣言/ 定義の種類によります）。

前方（先行）宣言の場合、: キーワードforward とセミコロン（;）
エントリ定義の場合、: キーワードis の後に演算子シーケンス、その後にキーワードend （その後にオプションでキーワードentry）、その後にセミコロン（;）。
代替エントリ定義の場合、: 左中カッコ（{）、演算子シーケンス、その後に右中カッコ（}）

プログラムの動作中、処理がエントリの演算子シーケンスの最後まで達すると、演算子stop（暗黙の演算子）が実行されます。

下は、リアルタイムアプリケーションのエントリの例です。このエントリは、受信コールを受け付けるかどうかチェックし、受け付けに成功するとサウンドを再生します。エントリコードの処理が終わるとプログラムが終了し、したがって呼び出しも終了します。

entry main is
  if acceptCall() == null then
    playFile("greeting.wav");
  end if;
end entry;

下記は、上記のエントリの代替フォーム（代替エントリ定義）です。条件演算子の部分が代替フォームです。

entry main {
  if (acceptCall() == null) {
    playFile("greeting.wav");
  }
}

プロシージャ

プロシージャの宣言は、キーワードprocedureとプロシージャの名前、左丸カッコ、パラメータ名のリスト（オプション）、右丸カッコに加え、次の要素で構成されます（宣言/ 定義の種類によります）。

前方宣言の場合、: キーワードforward とセミコロン（;）
プロシージャ定義の場合、: キーワードis、演算子シーケンス、キーワードend （オプションで、その後にキーワードprocedure）、最後にセミコロン（;）
代替プロシージャ定義の場合、: 左中カッコ（{）、演算子シーケンス、その後に右中カッコ（}）
外部宣言の場合、: キーワードexternal と、その後にセミコロン（;）

プログラムの動作中、処理がプロシージャの演算子シーケンスの最後まで達すると、演算子return （暗黙の演算子）が実行されます。

下記はリアルタイムアプリケーションプロシージャの例で、このプロシージャでは、数値が読み上げられます。

procedure sayNumber(x) is
  x = x % 100;
  if x >= 10 then
    PlayFile(String(x/10*10)+".wav");
  end if;
  if x != 0 then
    PlayFile(String(x%10)+".wav");
  end if;
end procedure;

前方宣言を使用する場合、その前方宣言で指定されているパラメータとまったく同じパラメータをプロシージャ定義で指定しなければなりません。下は例です。

例：

procedure SayMoney(x,units) forward;
procedure sayNumber(x) forward;
procedure sayMoney(x,units) is
sayNumber(x);
PlayFile(units+".wav");
end procedure;

関数

関数の宣言は、プロシージャの宣言と基本的には同じです。違いは、キーワードprocedure の代わりにキーワードfunction を使用することだけです。

関数コードセクションのプログラム制御パスはすべて、return またはstop のいずれかの演算子で終わらなければなりません。

次は、引数の階乗を返す関数の例です。

function Factorial(x) is
if x <= 1 then return 1; end if;
return Factorial(x-1)*x;
end function;

次は、上記と同じ関数を代替フォーム、また三項演算子を使って定義した例です。

function Factorial(x) {
return x <= 1 ? 1 : Factorial(x-1)*x;
}

同一のプログラムコードでは、コードセクション（エントリ、プロシージャ、関数）の名前はいずれも一意でなければなりません。

以下、CG/PL に内蔵されているプロシージャと関数について説明します。いずれも、すべてのアプリケーションで使用できます。下記の内蔵プロシージャと内蔵関数の名前は、ユーザー定義のプロシージャまたは関数の名前として使用することはできません。

Same(arg1,arg2): この関数では、arg1 （引数1）とarg2 （引数2）の値がどちらも同じオブジェクト、両方の値がNULL 値、両方の値がTRUE 値のいずれかの場合、TRUE 値が返ります。これ以外のときには、NULL 値が返ります。
例えば、Same("J" + "ack","Jack") の値はNULL 値です。
次の例の場合、
x = "my string";
y = "my string";
z = x;
test1 = Same(x,y);
test2 = Same(x,x);
test3 = Same(x,z);
test1 の値はNULL 値です。一方、test2 とtest3 の値はどちらもTRUE 値です。
Length(arg): argが文字列の場合、この関数からは、その文字列のサイズ（バイト数）が返ります。　　
argがデータブロックの場合、この関数からは、そのデータブロックのサイズ（バイト数）が返ります。
argが配列の場合、この関数からは、その配列の要素の数が返ります。
argが辞書の場合、この関数からは、その辞書のキー（要素）の数が返ります。
argがメールボックスハンドルの場合、この関数からは、そのメールボックスのメッセージの数が返ります。
上記以外の場合、この関数からは数値0 が返ります。
Void(arg1): このプロシージャはarg1の値を廃棄するだけで、他には何も処理は行われません。通常、関数を呼び出し、その結果が不要なときに使用します。

文字列

IsString(arg): この関数からは、argの値が文字列のときにTRUE 値が返ります。そうでない場合、NULL 値が返ります。
String(arg): この関数は、argの値が文字列の場合、その文字列を返します。
argの値が数値の場合、その数値を10 進数で表した文字列を返します。
argの値がIP アドレスの場合、そのIP （ネットワーク）アドレスを標準の形式で表した文字列を返します。
argの値がNULL 値の場合、NULL 値を返します。
上記以外の場合、　その値をテキスト表現で表した文字列が返ります。
FindSubstring(str,substr): str とsubstr の値がどちらも文字列で、かつ、substr の値がstrのサブ文字列（文字列の一部）だった場合、この関数からは、文字列strの中のサブ文字列substrの位置（先頭の位置が0）が返ります。
例えば、FindSubstring("forest","for") の値は 0です。
上記以外の場合、数値 -1が返ります。
Substring(str,from,len): str の値が文字列で、かつfrom の値が数値、かつlen の値が非負値の場合、この関数からは、文字列strのうち長さがlenのサブ文字列が返ります。
fromが非負値（正の値）の場合、fromで示される位置（文字列の先頭の文字の位置が0）から始まるサブ文字列が返ります。
fromが負の値の場合、文字列strの最後から数えて1- fromの位置で終わるサブ文字列が返ります（したがって、文字列の最後の文字も含めてサブ文字列を取り出したい場合、fromを-1 とします）。
from の値（または1- from の値）がstr の長さ以上の場合、空白の文字列が返ります。
from の値＋ lenの値（または1- from の値＋ enの値）がstr の長さより大きい場合、返る文字列の長さはlenより短くなります。
上記以外の場合、この関数からはNULL 値が返ります。
EOL(): この関数からは、EOL （行の終わり）記号を格納した文字列が返ります。EOL 記号は、使用しているOS プラットフォームによって異なります。
CRLF(): この関数からは、インターネットEOL （<carriage-return><line-feed>）記号が返ります。
ToUpperCase(str): strの値が文字列の場合、その文字列の文字がすべて大文字に変換された文字列が返ります。
ToLowerCase(str): strの値が文字列の場合、その文字列の文字がすべて小文字に変換された文字列が返ります。
FindRegEx(str,picture): この関数では、文字列str と文字列picture （正規表現を指定）の比較が可能です。
strまたはpictureが文字列でなかった場合、または文字列pictureが正規表現と解釈されなかった場合、または文字列strがpictureの正規表現と一致しなかった場合、この関数からは NULL 値が返ります。
上記以外の場合、文字列の配列が返ります。配列の要素0 には文字列strのコピーが格納されています。それ以外の要素には（ある場合）、文字列strのサブ文字列のうち正規表現グ
ループに一致したサブ文字列が格納されています。文字列pictureに指定する正規表現は、拡張POSIX シンタックスの正規表現でなければなりません。
EmailDomainPart(address): addressの値が文字列（アドレス）で、かつ、その文字列に@ 記号がある場合、最初の@ 記号の後のアドレスを格納した文字列（つまりドメイン部）が返ります。
上記以外の場合、戻り値はNULL 値です。
EmailUserPart(address): addressの値が文字列でない場合、この関数はNULL 値を返します。
addressの値が文字列であるものの、@ 記号が存在しない場合、この関数は、その文字列をそのまま返します。
上記以外の場合（ addressの値が文字列であり、かつ@ 記号が存在する場合）、この関数からは、最初の@ 記号の前のアドレスを格納した文字列（つまりユーザー部）が返ります。

数値

IsNumber(arg): argの値が数値の場合、この関数はTRUE 値を返します。それ以外の場合、NULL 値が返ります。
Number(arg): argの値が数値の場合、この関数は、その数値を返します。
argの値が文字列の場合、その文字列の数値が返ります（数値への変換）。数値への変換は、最初の非数値文字の前まで行われます。
例えば、 Number("123#") の場合、 123が返ります。
上記以外の場合、この関数からは数値 0が返ります。
RandomNumber(): この関数は、整数の乱数を返します。範囲は、[0..9223372036854775807] ([0..2*63- 1]) です。

タイムスタンプ

IsDate(arg): argの値がタイムスタンプの場合、TRUE 値が返ります。そうでない場合、NULL 値が返ります。
GMTTime(): この関数は、カレントのGMT 時刻を格納したタイムスタンプオブジェクトを返します。
LocalTime(): この関数は、カレントのローカル時刻を格納したタイムスタンプオブジェクトを返します
GMTToLocal(arg): argの値としてタイムスタンプオブジェクト（GMT）を指定した場合、その値がローカル時刻に変換され、タイムスタンプオブジェクトとして返ります。
上記以外の場合、この関数はNULL 値を返します。
LocalToGMT(arg): argの値としてタイムスタンプオブジェクト（ローカル時刻）を指定した場合、その値が GMT に変換され、タイムスタンプオブジェクトとして返ります。
上記以外の場合、この関数はNULL 値を返します。
Year(arg): argの値がタイムスタンプオブジェクトの場合、argの値のうち年の数値が返ります。
上記以外の場合、この関数はNULL 値を返します。
Month(arg): argの値がタイムスタンプオブジェクトの場合、argの値のうち月の名前（Jan, Feb, Mar, Apr, May, Jun, Jul, Aug, Sep, Oct, Nov, Dec）を格納した文字列が返ります。　　
上記以外の場合、この関数はNULL 値を返します。
MonthNum(arg): argの値がタイムスタンプオブジェクトの場合、argの値のうち月の数値（1 月は1）が返ります。
上記以外の場合、NULL 値が返ります。
MonthDay(arg): argの値がタイムスタンプオブジェクトの場合、argの値のうち月の日を示す数値（月の最初の日が1）が返ります。
上記以外の場合、NULL 値が返ります。
WeekDay(arg): argの値がタイムスタンプオブジェクトの場合、argの値のうち曜日の名前（Mon, Tue, Wed, Thu, Fri, Sat, Sun)を格納した文字列が返ります。
上記以外の場合、NULL 値が返ります。
YearDay(arg): argの値がタイムスタンプオブジェクトの場合、argの値のうち年の日を示す数値（1 月1 日が1）が返ります。
上記以外の場合、NULL 値が返ります。
TimeOfDay(arg): argの値がタイムスタンプオブジェクトの場合、argの日の値と、その日の開始点との差を示す数値（日の開始から経過した時間の長さ、単位は秒数）が返ります。　
上記以外の場合、NULL 値が返ります。
DateNumber(arg): argの値がタイムスタンプオブジェクトの場合、1970 年1 月1 日からargの値の中の日までの日数（経過日数）が返ります。
上記以外の場合、NULL 値が返ります。
DateByMonthDay(year,monthNum,monthDay): year、monthNum、monthDay （年の数値、月の数値、月の日の数値）はすべて正の数値でなければなりません。いずれかが正の数値でなかったときには、この関数からはNULL 値が返ります。すべて正の数値だった場合、year、monthNum、monthDay で指定した日の午前０時を格納したタイムスタンプオブジェクトが返ります。
例えば、次の場合、2006 年11 月5 日の午前０時のタイムスタンプが返ります。
DateByMonthDay(2006,11,5)
DateByYearDay(year,yearDay): year、yearDay （年の数値、年の日の数値）はどちらも正の数値でなければなりません。いずれかが正の数値でなかったときには、この関数からはNULL 値が返ります。すべて正の数値だった場合、year、yearDay で指定した日の午前０時を格納したタイムスタンプオブジェクトが返ります。
例えば、次の場合、2006 年2 月1 日の午前０時のタイムスタンプが返ります。
DateByYearDay(2006,32)

IP アドレス

IsIPAddress(arg): argの値がIP アドレスの場合、この関数からはTRUE 値が返ります。そうでない場合、 NULL 値が返ります。
IPAddress(arg): argの値がIP アドレスの場合、そのIP アドレスが返ります。
argの値が文字列で、その文字列に格納されているIP アドレス表現が適切（オプションでポート番号があっても可）だった場合、そのIP アドレスが返ります。
上記以外の場合、NULL 値が返ります。

データブロック

IsData(arg): argの値がデータブロックの場合、TRUE 値が返ります。それ以外の場合、NULL 値が返ります。

配列

IsArray(arg): argの値が配列の場合、TRUE 値が返ります。それ以外の場合、NULL 値が返ります。
NewArray(): この関数では、新規の空の配列が作成され、その配列が返ります。
Invert(arg): argの値は配列でなければなりません。そうでない場合、プログラム例外が発生します。
argの値（配列）の要素の順番が逆転された後、その配列が返ります。
Find(source,object): sourceには配列、objectにはオブジェクトを指定します。関数の実行後、sourceの要素のうちobjectの値に等しい最初の要素のインデックスが返ります。配列sourceに該当するオブジェクトがなかった場合、負の数値が返ります。
sourceの値が配列でないときには、負の数値が返ります。
RemoveElement(target,index): このプロシージャでは、配列の要素を削除できます。
targetの値は配列でなければならず、そうでない場合、プログラム例外が発生します。
indexは配列の要素のインデックスで、値は数値または10 進数値を格納した文字列でなければなりません。ここで指定した配列の要素が削除されます。indexを指定しなかったときには、配列の最初の要素（インデックス0）が削除されます。
例えば配列myArray の値が (1,4,9,16,25)の場合、 RemoveElement(myArray,2) により配列myArray の値は (1,4,16,25)に変更されます（インデックスが2 の要素が削除されます）。
InsertElement(target,index,element): このプロシージャを使って、配列に要素を挿入できます。
targetの値は配列でなければならず、そうでない場合、プログラム例外が発生します。
indexは配列の要素のインデックスで、値は数値または10 進数値を格納した文字列でなければなりません。indexで指定した位置に要素が挿入されます。既存の要素のうち、indexで指定した位置にある要素と、それ以降の要素のインデックスはそれぞれ1 だけ増えます。
例えば配列myArray の値が (1,4,9,16,25) の場合、 InsertElement(myArray,2,"Jack") により配列myArray の値は (1,4,"Jack",9,16,25) に変更されます（インデックスが2 の位置に要素が挿入されます）。

辞書

IsDictionary(arg): argの値が辞書の場合、TRUE 値が返ります。それ以外の場合、NULL 値が返ります。
NewDictionary(): この関数を使って、新規の空の辞書を作成できます。

データ変換

ObjectToString(arg): この関数では、argの値のテキスト表現を格納した文字列が返ります（オブジェクトからテキストへの変換）。
argの値がNULL 値の場合、NULL 値が返ります。
TextToObject(arg): argの値は文字列またはデータブロックでなければなりません。そうでない場合、プログラム例外が発生します。
この関数では、argの値に対応するオブジェクトが返ります（テキストからオブジェクトへの変換）。変換が失敗した場合、NULL 値が戻ります。

環境

Vars()

アドレスとURI

SIPURIToEmail(uri): uriにSIP URI を指定し、そのURI を電子メール文字列に変換できます。
uriが文字列でなかったとき、またはSIP URI であると認識されなかったときには、この関数からはNULL 値が返ります。
EmailToSIPURI(email): emailに電子メールアドレスを指定し、そのアドレスをSIP URI 文字列に変換できます。
emailが文字列でなかったとき、または電子メールアドレスであると認識されなかったときには、この関数からはNULL 値が返ります。
PhoneNumberToSIPURI(phoneNumber): この関数は、phoneNumberの値（電話番号）をSIP URI 文字列に変換します。
phoneNumberが文字列でなかったとき、または電話番号であると認識されなかったときには、NULL 値が返ります。
phoneNumberの値に書式付け記号があった場合、その記号はすべて削除され、数字と先頭のプラス（+）記号（ある場合）だけが残ります。
また、処理後の電話番号に自動的にカレントのドメイン名が付加されます。
RouteAddress(email,type)

アカウントデータ

以下の関数とプロシージャは、アカウントデータ操作用です。いずれもプログラム（タスク）に「カレントのアカウント」が設定されているときに使用できます。

MyDomain(): カレントタスクに、カレントのドメイン名（カレントのアカウントのドメインの名前）が存在する場合、その名前を格納した文字列が返ります。存在しない場合、NULL 値が返ります。
MyEmail(): カレントタスクに、カレントのアカウントの電子メールアドレスが存在する場合、その電子メールアドレスを格納した文字列が返ります。存在しない場合、NULL 値が返ります。
GetAccountPreferences(keyName): カレントのアカウントに設定されているプレファレンスデータが返ります。
のキーの値（アカウントのプレファレンスオブジェクト）が返ります。指定しなかった（空白の文字列の）場合、アカウントの有効なプレファレンスがすべて格納された辞書が返ります。
keyNameには接頭辞~username/ を付加できます（この接頭辞は自動的に削除されます）。これで、username で指定したアカウント（ユーザー名）について処理が行われます。この場合、そのアカウントがカレントのアカウントと同じではなく、かつ、カレントのアカウントに、そのアカウントのドメインについてドメイン管理者アクセス権が付与されているときに限って、処理が実行されます。
SetAccountPreferences(keyValue,keyName): この関数では、カレントのアカウントのプレファレンスデータを更新できます。
keyNameには辞書（アカウントのプレファレンスデータ）のキーの名前（文字列）、keyValue には、そのキーの新規のオブジェクトを指定します。既存のオブジェクトは、このオブジェクトに更新されます。keyValueにNULL 値を指定した場合、そのオブジェクトがアカウントのプレファレンスデータから削除されます。以後、そのキーの値としてデフォルト値が使用されます。
keyNameを指定しない（空白の文字列を指定）場合、keyValueには辞書を指定します。この方法で、アカウントのプレファレンスデータ全体を更新できます。
keyNameには接頭辞~username/ を付加できます（この接頭辞は自動的に削除されます）。これで、username で指定したアカウントのデータを更新できます。その場合、そのアカウントがカレントのアカウントと同じではなく、かつ、カレントのアカウントに、そのアカウントのドメインについてドメイン管理者アクセス権が付与されているときに限って、処理が実行されます。
プレファレンスデータの更新に成功したときには、NULL 値が返ります。失敗したときには、エラーコードを格納した文字列が返ります。
ReadSiteFile(fileName)

注意: カレントのアカウント以外のアカウントのファイルストレージにもアクセスできます。その場合、次の書式でファイル名またはフォルダ名を指定します。

Impersonate(email): この関数では、emailに電子メールアドレスを指定し、そのアドレスをルートできます。結果は、カレントのアカウントで使用されます。
ルート先のアドレスがローカルアドレスでなかった場合、カレントのアカウントは消去されます。
ルート先のアドレスがローカルアドレスで、かつ、そのアドレスがカレントのアカウントのアドレスと異なっている場合（例えば別のドメイン）、カレントのアカウントに、ルート先のアドレスのドメインについて［CanImpersonate］アクセス権が付与されているときに限って処理が実行されます。
ルーティングによりカレントのアカウントが変更された場合、プレファレンスや言語、時刻ゾーンも変更されます。
処理に成功するとNULL 値が、失敗するとエラーコードを格納した文字列が返ります。
ReadGroupMembers(groupName): この関数では、カレントのドメインに関する情報（グループのメンバー）を取り出せます。
groupNameにはグループの名前（文字列）を指定します。このグループに関する情報が読み出されます。
処理に成功すると文字列の配列が返り、各文字列にはグループのメンバーの電子メールアドレスが格納されています。指定した名前のグループが存在しなかったときには、NULL 値が返ります。
ReadTelnums(accountName): This function reads Phone Numbers assigned to the accountName Account or to the current Account, if the accountName value is a null-value.
This function returns an array of strings. This function returns a null-value if there is no Account with the specified name.
To retrieve the Phone Numbers assigned to a different Account, the current Account should have the Domain Administrator right for the accountName Account Domain.
UpdateAccountMailRule(ruleData,accountName)
UpdateAccountSignalRule(ruleData,accountName): These functions modify Account Queue or Signal Rules.
The ruleData parameter is a string or an array. It has the same meaning as the newRule parameter of the UpdateAccountMailRule and UpdateAccountSignalRule CLI commands.
These functions update the Rules of the the accountName Account, or the current Account if the accountName value is a null-value.
To update Queue Rules of a different Account, the current Account should have the RulesAllowed Domain Administrator right for the accountName Account Domain.
To update Signal Rules of a different Account, the current Account should have the SignalRulesAllowed Domain Administrator right for the accountName Account Domain.
This function returns a null-value if the operation has succeeded, otherwise it returns a string with an error code.

メールボックスハンドル

メールボックスハンドルは、メールボックスを表す内部オブジェクトです。

OpenMailbox(mailboxName): この関数を使ってメールボックスをオープンできます。mailboxNameは文字列でなければなりません。このパラメータにはメールボックス名を指定します。
メールボックス名の先頭に~ 記号を付けなかった場合、カレントのアカウント（存在する場合）を使ってメールボックスがオープンされます（~ 記号を付加し、別のアカウントを指定することができます）。
カレントのアカウント（存在する場合）には、mailboxNameで指定したメールボックスについて読み取り/ 選択が付与されていなければなりません。
メールボックスのオープンに成功した場合、メールボックスハンドルが返ります。失敗したときには、NULL 値が返ります。
MailboxUIDs(boxRef,flags): この関数からは、メールボックスメッセージUID （メールボックスにあるメッセージのUID）の配列が返ります。
boxRefには、メールボックスハンドルを指定します。
flagsにはメッセージフラグを指定します。複数指定することができ、その場合、コンマで区切ります。通常のメッセージフラグの名前のほか、逆名を（例えばUnseen）指定することもできます。メッセージのうち、通常の名前（Seen など）を使って指定したフラグが設定されており、かつ、逆名（Unseen など）を使って指定したフラグが設定されていないメッセージのUID だけが配列で返ります。
次の例では、　フラグSeen が設定されており、かつ、フラグDeleted が設定されていないメッセージのUID が取り出されます。
myMailbox = OpenMailbox("INBOX");
seen = MailboxUIDs(myMailbox,"Seen,Undeleted");
MailboxInternalTimeByUID(boxRef,uid): この関数からは、メッセージの内部日付を格納したタイムスタンプオブジェクトが返ります。
boxRefの値としてはメールボックスハンドルを指定します。uidには、数値（メッセージ UID）を指定します。
指定したUID のメッセージがメールボックスに存在しなかったときには、この関数から NULL 値が返ります。
MailboxFlagsByUID(boxRef,uid): メールボックスのメッセージのフラグの名前を格納した文字列（コンマ区切りのリスト）が返ります。
boxRefの値としてはメールボックスハンドルを指定します。uidには、数値（メッセージ UID）を指定します。
指定したUID のメッセージがメールボックスに存在しなかったときには、この関数から NULL 値が返ります。
MailboxSetFlagsByUID(boxRef,uid,flags): この関数を使ってメールボックスのメッセージのフラグを変更できます。
boxRefの値としてはメールボックスハンドルを指定します。uidには、数値（メッセージ UID）を指定します。flagsには、メッセージフラグの名前または逆名を指定します。複数指定する場合、コンマで区切ります。
名前を使って指定したフラグが、指定したメッセージのフラグとして設定されます。また、逆名の場合、そのフラグがリセット（例えばUnseen とした場合、Seen がリセット）されます。
カレントのアカウント（存在する場合）にフラグの変更に関する所定のメールボックスアクセス権が付与されており、かつフラグの変更に成功した場合、NULL 値が返ります。そうでない場合、エラーコード文字列が返ります。
MailboxExpunge(boxRef): メールボックスのメッセージのうち、　"purgable （パージ可能） " または"deleted （削除済み） " とマークされているメッセージをすべて削除できます。
boxRefにはメールボックスハンドルを指定します。uidには、数値（メッセージUID）を指定します。
MailboxAudioByUID(boxRef,uid): この関数からは、メッセージのオーディオ部分を格納したデータブロックが返ります。　　 boxRefにはメールボックスハンドルを指定します。uidには、数値（メッセージUID）を指定します。
指定したUID のメッセージがメールボックスに存在しなかったときには、NULL 値が返ります。
MailboxRedirectByUID(boxRef,uid,addresses)
MailboxForwardByUID(boxRef,uid,addresses): These function redirect or forward the specified message to the specified E-mail addresses.
The boxRef value should be a mailbox handle, the uid value should be a number - the message UID, the addresses should be a string containing one E-mail address or several E-mail addresses separated with the comma (,) symbols.
These functions return a null-value if the operation has succeeded, otherwise they return a string with an error code.

ディレクトリ

以下の内蔵関数は、ディレクトリマネージャへのインターフェイスとして使用できます。

DirectorySearch(baseDN,filter,parameters)

ディレクトリ検索が可能です。見つかったレコードを格納した辞書が返ります。
baseDNには検索ベースDN を指定します。"$" を指定することもでき、その場合、ディレクトリ統合設定を使ってカレントのドメインの検索ベースDN が生成されます。
filterには、NULL 値または検索フィルタ（文字列、RFC2254 フォーマット）を指定します。
parametersにはNULL 値、または検索オプション（下記）を格納した辞書を指定します。

limit: このオプションに正の値を指定しておくと、最大で、この数までのレコードが返ります。指定しなかった場合、レコードの最大数として100 がデフォルトで使用されます。
keys: このオプションの値としてDN を指定しておくと、辞書のキーとして正規のレコードDN （識別名）が使用されます。指定しなかった場合、RDN （相対識別名）が辞書のキーとして使用されます。
scope: このオプションの値としてsub を指定しておくと、サブツリー検索が実行されます。指定しなかった場合、ベースDN レコードの子ディレクトリが検索されます。
attributes: このオプションの値として属性（文字列）の配列を指定しておくと、その配列に指定した属性だけがレコードに取り込まれます。指定しなかった場合、すべての属性がレコードに取り込まれ返ります。

ディレクトリ検索に失敗すると（ベースDN レコードが存在しない、アクセス権が不十分など）、エラーコード文字列が返ります。

サービス

GetLanguage(): この関数からは、現在選択されている言語を格納した文字列が返ります。
SetLanguage(lang): このプロシージャを使って、「現在選択されている言語」を設定できます。langには言語名（文字列）を指定します。NULL 値を指定した場合、デフォルトの言語が選択されます。
GetTimeZoneName(): この関数からは、現在選択されているタイムゾーンの名前が返ります。タイムゾーンが選択されていない（サーバータイムオフセットが使用されている）場合、この関数はNULL 値を返します。
SetTimeZone(zoneName): このプロシージャでは、カレントのタイムゾーンの設定が可能です。zoneNameには有効なタイムゾーンの名前（文字列）を指定します。タイムゾーンの名前が無効だった（存在しなかった）とき、または文字列でなかったときには仮想の値（ no zone）が設定され、また、サーバーのカレントのタイムオフセットが使用されます。
SysLog(arg): このプロシージャでは、argにテキスト表現を指定し、そのテキストをサーバーログに格納できます。

通信

HTTPCall(URL,parameters)

この関数を使ってHTTP トランザクション（HTTP コール）を実行できます。
URLは文字列でなければなりません。URLには要求URL を指定します。URL スキーマは、 http またはhttps のいずれかです。
parametersには辞書を指定します。辞書の内容は各要求パラメータです。要求の本体を指定することもできます。辞書の要素としては、下記の要素を指定できます（すべてオプションです）。

body: 要求の本体（ボディ）を格納したデータブロック。
Content-Type: 要求の本体のコンテントタイプを格納した文字列。この要素は、要素body を指定したときにだけ使用されます。
Content-Subtype: 要求の本体のコンテントサブタイプを格納した文字列。この要素は、要素body と要素Content-Type を指定したときにだけ使用されます。
method: 要求のメソッドを格納した文字列。この要素を指定しなかった場合、GET メソッド（要求の本体を指定しなかったとき）またはPOST メソッド（要求の本体を指定したとき）が使用されます。
Cookie: Cookie フィールドデータを格納した文字列。
authName, authPassword: 認証名と認証パスワード（どちらも文字列）です。指定した場合、この2 つの文字列を使って要求の認証が行われます。

HTTP トランザクションが失敗したときにはエラーコード文字列が返ります。成功したときには、次の各要素を格納した辞書が返ります。

responseCode: HTTP 応答コードが格納された数値。
body: 応答の本体を格納したデータブロック（空のこともあります）
Content-Type: 応答の本体のコンテントタイプを格納した文字列。
Content-Subtype: 応答の本体のコンテントサブタイプを格納した文字列。
charset: 応答の本体のキャラクタセットを格納した文字列。
Date, Last-Modified, Expires: タイムスタンプで、それぞれ応答のヘッダフィールド（日付、最後の更新時刻、有効期限）の値が格納されています。
Server, Location, Set-Cookie: 文字列で、それぞれ応答のヘッダフィールド（サーバー、場所、セットクッキー）の値が格納されています。

SendEMail(fromAddress,subject,to,headers,content)

この関数では、電子メールメッセージの作成と送信が可能です。
fromAddressの値は文字列でなければなりません。このパラメータには、メッセージのFrom: アドレスを指定します。
subjectの値は文字列でなければなりません。このパラメータには、メッセージのSubject: フィールドを指定します。
toの値は、単一の電子メールアドレス（文字列）または電子メールアドレス（文字列）の配列でなければなりません。メッセージのTo: アドレス（単一または複数）です。
headersにはNULL 値または辞書を指定します。この辞書で指定したヘッダフィールドの値が、作成された電子メールメッセージで使われます。辞書には、次の要素を指定できます（すべてオプションです）。

Cc: この要素には、電子メールアドレス（文字列）または電子メールアドレス（文字列）の配列を指定します。指定した値は、メッセージのCc: アドレス（単一または複数）として使用されます。
Bcc: この要素には、電子メールアドレス（文字列）または電子メールアドレス（文字列）の配列を指定します。指定した値は、メッセージのBcc: アドレス（単一または複数）として使用されます。
sourceType: この要素には、メッセージソース（文字列）を指定します。この要素を指定しなかった場合、値として文字列""CGPL" が使われます。
sourceAddress: この要素の値は文字列でなければなりません。この要素には、メッセージソースのアドレス（ネットワークアドレス、リモートシステムの名前など）を指定します。
protocol: この要素の値は文字列でなければなりません。この要素にはプロトコルを指定します。このプロトコルを使って、メッセージが送信されます。
Content-Class: この要素の値は文字列でなければなりません。この要素には、電子メールのCon-tent-Class: ヘッダフィールドの値を指定します。
X-Priority: この要素の値は文字列でなければなりません。この要素には、電子メールのX-Priority:ヘッダフィールドの値を指定します。

contentには、電子メールメッセージのボディ（本体）を指定します。contentの値が辞書の場合、辞書の要素のうちボディ（body）を示す要素の値が実際のコンテントとなります。これ以外の要素はすべて、ボディパラメータ（コンテントヘッダフィールド）です。contentの値が辞書でない場合、その値自体が実際のコンテントとして処理され、またボディパラメータは空です。
ボディパラメータ（辞書の要素）としては、次の要素が処理されます（すべてオプションです）。

Content-Type: この要素の値は文字列でなければなりません。この要素にはボディのコンテントタイプを指定します。この要素が指定されていない場合、コンテントタイプは"text" （コンテントが文字列の場合）または "application" （コンテントが文字列でない場合）のいずれかに設定されます。
Content-Subtype: この要素の値は文字列でなければなりません。この要素にはボディのコンテントサブタイプを指定します。この要素が指定されていなく、かつコンテントタイプ（Content-Type）が "text"に設定されている場合、この要素の値（コンテントサブタイプ）としては "plain" が使われます。
filename: この要素の値は文字列でなければなりません。この要素には、ファイル名（ボディを格納したファイルの名前）を指定します。
Content-Disposition: この要素の値は文字列でなければなりません。この要素には、コンテントディスポジションを指定します。この要素が指定されておらず、要素fileName が指定されている場合、コンテントディスポジションの値としては "attachment" が使われます。

実際のコンテントが文字列の場合、8bit コンテントトランスファーエンコーディングを使って「そのまま」保存されます。
実際のコンテントがデータブロックの場合、base64 コンテントトランスファーエンコーディングを使って保存されます。
実際のコンテントが配列の場合、コンテントはマルチパートコンテントとして処理されます。また、要素としてはコンテントサブタイプ（Content-Subtype）だけが使用されます。コンテントサブタイプが指定されていないときには、その値として "mixed" が使用されます。
配列の各要素はいずれも、contentの値自体の形式で保存されます。
実際のコンテントが配列、文字列、データブロックのいずれでもない場合、空のコンテントが保存されます。
電子メールメッセージの生成と送信（キューへの送信）に成功した場合、この関数からは NULL 値が返ります。失敗したときには、エラーコード文字列が返ります。

次は、簡単なテキストメッセージを送信する例です。

result = SendEmail("from@sender.dom","Test Message","To@recipient.dom",
null,"Test Message\eEnd Of Message\e");

次の例では、multipart/mixed メッセージが送信されます。このメッセージには、HTML テキストとバイナリアタッチメントが格納されています。

  content = NewArray();

  textPart = NewDictionary();
  textPart.("Content-Type") = "text";
  textPart.("Content-Subtype") = "html";
  textPart.body = "<HTML><BODY>This is an <B>HTML</B> text</BODY></HTML>";
  content[0] = textPart;

  dataPart = NewDictionary();
  dataPart.("Content-Type") = "image";
  dataPart.("Content-Subtype") = "gif";
  dataPart.fileName = "file.gif";
  dataPart.body = ReadSiteFile(dataPart.fileName);
  content[1] = dataPart;

  headers = NewDictionary();
  headers.("Content-Class") = "message";

  result = SendEmail("from@sender.dom","Test Attachment",
                     "To@recipient.dom",headers,content);

SendInstantMessage(fromAddress,toAddress,content)

この関数では、インスタントメッセージの作成と送信が可能です。
fromAddressの値は文字列でなければなりません。メッセージのFrom: アドレスです。
toAddressの値は文字列でなければなりません。メッセージのTo:（受取人）アドレスです。
contentの値は文字列でなければなりません。メッセージのコンテントです。
この関数による処理は、インスタントメッセージのシグナリング処理（生成と送信）の開始だけで、処理が完了（応答の受信）まで待機することはありません。
インスタントメッセージの生成と送信（Signal コンポーネントへの送信）に成功すると NULL 値が返ります。失敗したときには、エラーコード文字列が返ります。

RADIUSCall(address,parameters)

この関数では、RADIUS 要求の生成と送信が可能です。
addressの値はIP アドレスでなければなりません。RADIUS サーバーのアドレスとポートを指定します。このRADIUS サーバーに要求が送信されます。
parametersの値は辞書でなければならず、辞書の要素は次の通りです。

Type: この要素は文字列でなければなりません。この要素は、送信されるRADIUS 要求のタイプです。指定できるタイプは次の通りです。
authenticate, accountingStart, accountingUpdate, accountingStop.
Secret: この要素は文字列でなければなりません。この要素には、RADIUS サーバーの「共有秘密（shared secret）」を指定します。
Username: この要素は文字列（ユーザー名）でなければなりません。このユーザー名を使って、要求のuserName (1) 属性が作成されます。
Password: RADIUS 要求のタイプがauthenticate の場合（上記）、この要素は必ず指定されていなければなりません。文字列でなければなりません。クリアテキストパスワードを指定し、このパスワードを使って認証が行われます。
nn (nn は10 進数）: この要素を使って、要求の追加の属性（複数可）を指定できます（属性を示す値を指定します）
要素の値は、文字列、数値（整数型パラメータの場合）、IP アドレス（インターネット型パラメータの場合）のいずれかでなければなりません。
要素の値としてデータブロックを指定することもでき、その場合、そのデータブロックのないようなエンコーディングなしで送信されます。
また、配列を指定することもでき、その場合、配列の要素の値がそれぞれ複数回にわたって要求に追加されます。
-nnnnn (where nnnnn is a decimal number)

RADIUS 処理が成功したときには、この関数からは辞書が返ります。この辞書には、RADIUS サーバーからの応答に含まれている属性が格納されています。処理が失敗した場合、エラーコードを格納した文字列が返ります。
注意: 要求は RADIUS モジュールのUDP ソケットを使って送信されます。したがって、 RADIUS モジュールが有効になっていなければなりません（また、0 以外のポート番号が使用されるように設定しておかなければなりません）。

次は、RADIUS 認証要求を送信する場合の例です。この要求は、nasIdentifier (32) 属性（テキスト）が格納されて送信されます。

callParam = newDictionary();
callParam.Type     = "authenticate";
callParam.Secret   = "sys2";
callParam.Username = "user4567";
callParam.Password = "drum$1245";
callParam.("32")   = "my NAS";
result = RADIUSCall(IPAddress("[10.0.1.77]:1812"),callParam);

次は、RADIUS アカウンティング要求の送信例です。この要求は、nasIdentifier (32) 属性（テキスト）とacctSessionTime (60) 属性（数値）が格納されて送られます。

callParam = newDictionary();
callParam.Type     = "accountingStart";
callParam.Secret   = "sys2";
callParam.Username = "user4567";
callParam.("32")   = "my NAS";
callParam.("46")   = SessionTimeInMinites*60;
result = RADIUSCall(IPAddress("[10.0.1.77]:1812"),callParam);

環境（リアルタイムアプリケーション環境など）によっては、マルチタスキング機能の利用が可能です。こうした環境（マルチタスキング環境）では、複数のプログラム呼び出し（タスク）の同時実行が可能であり、この同時実行により相互に通信したりデータを交換したりといった処理が可能です。以下、マルチタスキング環境で使用できるCG/PL について説明します。

タスクを表現する内部オブジェクトをタスクハンドルと呼んでいます。クラスタ環境では、タスクハンドルには、そのタスクが動作しているクラスタメンバーに対する参照も格納されています。

スポーニング

プログラム（実行中のタスク）には、スポーニング式を使って新規のタスクを作成する機能があります。スポーニング式とは、キーワードspawn の後にエントリコードポジションの名前を定義するという形式の式をいいます。
スポーニング式の値は、作成された新規のタスクのタスクハンドルです。または、新規のタスクに失敗したときには、NULL が返ります。

次は、プログラム（エントリコードセクションMain）で新規のタスクを作成する場合の例です。この新規のタスクにより、エントリコードセクションDoBackup が実行され、その結果、"file1"、 "file2"...."file100" の各ファイルが"backup1"、"backup2"... の各ファイルにコピーされます。

entry DoBackup is
  nameIndex = 1;
  while nameIndex <= 100 loop
    fileData = ReadSiteFile("file" + String(nameIndex));
    if fileData != null then
      resultCode = WriteSiteFile("backup" + String(nameIndex));
      if resultCode != null then
        Log("failed to backup file" + String(nameIndex) +
            ". Error Code=" + resultCode);
      end if;
    end if;
  end loop;
end entry;

entry Main is
  backuper = spawn DoBackup;
  if backuper == null then
    Log("Failed to start a Backup Task");
  end if;
end entry;

なお、複数のタスク間で変数が共有されることはいっさいありません。これは、タスク内で直接、スポーニング式を使って新規のタスクを作成したときでも同様です。

イベント

タスクから他のタスクにイベントを送信するという方法で、そのタスクと他のタスクとの間でデータの交換が可能です。

SendEvent(taskRef,eventName,eventParam)

ミーティング

ミーティング（会議）メカニズムはタスクに対応しており、このメカニズムを介して、アカウントのタスクと、そのアカウントの別のタスクとの間で通信が可能です。

アカウントではそれぞれ、名前付きミーティングセット（複数）と名前なしデフォルトミーティングセット（単一）を使用できます。ミーティングセットにはいずれも、複数の名前付きミーティングを作成できます。ミーティングは辞書オブジェクトで、それぞれタスクハンドルがあります（ない場合もあります）。

CreateMeeting(setName,key,param): この関数を使用して、カレントのアカウントのミーティングセットの中にミーティングオブジェクトを作成できます。
パラメータsetNameはミーティングセットの名前で、このミーティングセットを使ってミーティングが作成されます。この値がNULL 値または空白の文字列の場合、デフォルトミーティングセットが使用されます。
パラメータkeyは文字列でなければなりません。このパラメータには新規のミーティング（作成されるミーティング）の一意のID または名前を指定します。例えば、リアルタイムカンファレンシング（電子会議）アプリケーションの場合、乱数文字列を生成し、その乱数文字列をカンファレンスのパスワードとして使用し、さらに、その文字列をパラメータkeyの値として使用してミーティングを作成するという処理が可能です。その後、作成されたミーティング（また、そのミーティングを処理するタスクのタスクハンドル）に対して、同じアカウントの他のタスクからアクセスが可能になります。なお、その場合、他のタスクで、 CreateMeeting （ミーティング作成）処理で使用されているパラメータkey とパラメータ setName の値が認識されていることが必要です（パラメータを渡すことが必要です）。
パラメータparameterの値は、作成されたミーティングに保存されます。この場合、値はテキスト表現を使って保存されます。そのため、parameterの値また値のサブ要素として指定できるのは、標準のオブジェクトに限られます。例えば、メールボックスやタスクハンドルは、parameterの値また値のサブ要素としては指定できません。
ミーティングが作成された場合、この関数からはNULL 値が返ります。失敗したときには、エラーコード文字列が返ります。
ActivateMeeting(setName,key): この関数を使って、カレントのアカウントのミーティングに対してタスクハンドル（プログラムのカレントタスクのタスクハンドル）を追加できます。
setName とkey にはそれぞれ、既存のミーティングのsetName とkey の値を指定します。このミーティングに対してタスクハンドルが追加されます。
ミーティングに既にタスクハンドルが存在する場合、タスクハンドルを新たに追加することはできません。
この関数の処理が成功すると、カレントタスクがミーティングのアクティブタスクになります（ミーティングが有効になります）。
タスクハンドルの追加が成功すると、この関数からNULL 値が返ります。失敗すると、エラーコード文字列が返ります。
DeactivateMeeting(setName,key): この関数を使って、カレントのアカウントのミーティングに設定されているタスクハンドル（プログラムのカレントタスクのタスクハンドル）を削除できます。
setName とkey にはそれぞれ、既存のミーティングのsetName とkey の値を指定します。このミーティングのタスクハンドルが削除されます。
この関数の処理が成功すると、ミーティングにはアクティブタスクはなくなります（ミーティングが無効になります）。
タスクハンドルの削除に成功すると、NULL 値が返ります。失敗したときにはエラーコード文字列が返ります。
RemoveMeeting(setName,key): この関数では、カレントのアカウントのミーティングセットにあるミーティングを削除できます。
setName とkey にはそれぞれ、既存のミーティングのsetName とkey の値を指定します。このミーティングが削除されます。
ミーティングの削除に成功した場合、または指定したミーティングが見つからなかった場合、NULL 値が返ります。失敗したときにはエラーコード文字列が返ります。
FindMeeting(setName,key)

キュー

キューメカニズムはタスクに対応しており、このメカニズムを介して、アカウントのタスクと、そのアカウントの別のタスクとの間で通信が可能です。例えば、タスクを介して、キューに登録されているタスクを検索し、見つかったタスクをキューから削除するといった処理が可能です。

Enqueue(queueName,parameter,pty)

この関数では、カレントタスクをアカウントのキューに登録できます。
単一のアカウントでは複数のキューを使用できます。queueNameには、いずれかのキューの名前を指定します。このキューにタスクが登録されます。このパラメータの値としてNULL 値または空白の文字列を指定した場合、アカウントのデフォルトのキューが使用されます。
パラメータparameterにはタスクのパラメータの値を指定します。この値は、タスク（の登録情報）に保存されます。この場合、値はテキスト表現を使って保存されます。そのため、 parameterの値また値のサブ要素として指定できるのは、標準のオブジェクトに限られます。例えば、メールボックスやタスクハンドルは、parameterの値また値のサブ要素としては指定できません。
パラメータptyはタスクの優先度で、数値文字列でなければなりません。この文字列は、一桁の10 進数、ドット（.）、任意の桁の数値の書式で指定します。タスク（カレントタスク）は、この優先度をもとにキューに格納されます。具体的には、タスクは、そのタスクより pty（優先度）の値が小さいすべてのタスクの前、かつ、そのタスクとpty（優先度）の値が同じか、または大きいすべてのタスクの後に置かれます。パラメータptyの値としてNULL 文字列を指定した場合、デフォルト値として"1.0" が使われます。
同一のタスクは、キューが異なればそれぞれ別個に登録することができます。一方、同一のタスクを同一のキューに複数登録することはできません。つまり、タスク（カレントタスク）が既にキューに登録されており、そのタスクを使って、この関数で同じキューに登録を行おうとしても、タスクがもう一つ登録されることはありません。その場合、この関数のパラメータparameterを使って登録済みのタスクのパラメータparameterが更新され、また、この関数のパラメータptyの値にしたがってキューの現在のタスクの位置が更新されます（優先度が異なる場合）。
登録に失敗した場合、この関数からはNULL 値が返ります。登録に成功した場合、次の要素を格納した辞書が返ります。

length: 数値。キューに格納されているタスクの総数（長さ）です。
position: 数値。この関数によってキューに登録されたタスクの現在の位置。
キューの最初のタスクの位置は0 です。

CheckQueue(queueName)

アカウントのキューのカレントタスクの位置を取り出せます。
パラメータqueueNameにはキューの名前を指定します。このキューの中のタスクが検索されます。
指定したキューへのアクセスが失敗するとNULL 値が返ります。成功した場合、辞書が返ります。この辞書の要素は、関数Enqueue で返る辞書と同じです。
注意: 返った辞書の要素position には、指定したキューにカレントタスクが存在したときにのみ値が格納されています。カレントタスクがキューに存在していなかった場合、または、別のタスクによってキューから削除されていた場合には、この要素は空です。

Dequeue(queueName)

この関数を使って、アカウントのキューからカレントタスクを削除できます。
queueNameは、キューの名前です。このキューからカレントタスクが削除されます。

ReadQueue(queueName)

アカウントのキューの最初のタスクを取り出せます。
パラメータqueueNameにはキューの名前を指定します。
指定したキューにタスクが一つも存在しなかったときには、NULL 値が返ります。
指定したキューにタスクが存在したときには、次の要素を格納した辞書が返ります。

id

注意: この関数では、キューの最初のタスクは、取り出されると同時に削除されます。そのため、このタスクを再度同じキューに格納しない限り、別のタスクからこのタスクを検索することはできません。

string	::=	"string-data"
number	::=	digits
name	::=	alpha-numeric-and-underscore-starting-with-alpha

variable	::=	name

basicData	::=	variable \| funcCall
dataRef	::=	basicData \| dataRef [ expr ] \| dataRef . name \| dataRef . ( expr )
spawnExpr	::=	spawn name
basicExpr	::=	string \| number \| dataRef \| null \| false \| true \| spawnExpr

unaryOp	::=	! \| not \| - \| +
unary	::=	basicExpr \| unaryOp unary \| ( expr )
multOp	::=	* \| / \| %
multBinary	::=	unary \| multBinary multOp unary
addOp	::=	+ \| -
addBinary	::=	multBinary \| addBinary addOp multBinary
cmpOp	::=	< \| <= \| == \| != \| >= \| >
cmpBinary	::=	addBinary \| cmpBinary cmpOp addBinary
logicOp	::=	& \| and \| \| \| or \| && \| and then \| \|\| \| or else
logicBinary	::=	cmpBinary \| logicBinary logOp cmpBinary
ternary	::=	logicBinary \| logicBinary ? logicBinary : ternary
expr	::=	ternary

argList	::=	expr 0*(, expr)
funcCall	::=	name ( [argList] )
procCall	::=	name ( [argList] )

leftSide	::=	variable \| dataRef [ expr ] \| dataRef . name \| dataRef . ( expr )
letOper	::=	letOper = expr

nullOper	::=	\| null
stopOper	::=	stop
returnOper	::=	return [ expr ]

ifOper	::=	if expr then opSequence 0( elif* expr then opSequence ) [ else opSequence ] end [ if ]
altIfOper	::=	if expr { opSequence } 0( elif* expr { opSequence } ) [ else { opSequence } ]

loopOper	::=	[while expr ] loop opSequence 0( exitif* expr ; opSequence) end [ loop ]
altLoopOper	::=	while expr { opSequence 0( exitif* expr ; opSequence) }

oper	::=	nullOper \| procCall \| letOper \| returnOper \| stopOper \| ifOper \| loopOper
altOper	::=	altIfOper \| altLoopOper
seqOper	::=	oper ; \| altOper
opSequence	::=	0*( seqOper )

entryBody	::=	forward ; \| is opSequence end [ entry ] ; \| { opSequence }
procBody	::=	forward ; \| external ; \| is opSequence end [ procedure ] ; \| { opSequence }
funcBody	::=	forward ; \| external ; \| is opSequence end [ function ] ; \| { opSequence }
parmList	::=	name 0*(, name)
entry	::=	entry name entryBody
procedure	::=	procedure name ( [ paramlist] ) procBody
function	::=	function name ( [ paramlist] ) funcBody

program	::=	1*(entry \| procedure \| function)