Real-Time Application モジュール

• CGPL ファイル（複数可）。アプリケーションコードとコードモジュールが格納されています。
• VoiceXML ファイル（複数可）。アプリケーションコードが格納されています。
• 任意のサービスファイル（複数可）。例えば、記録済みメディアファイルなど。
• 言語ディレクトリ（複数可）。

リアルタイムアプリケーション環境は、複数の自然言語（話し言葉）をサポートしています。デフォ ルトの言語は英語です。英語以外の言語をサポートする場合、環境の中に「言語ディレクトリ」を作 成しなければなりません。言語ディレクトリの名前は、サポートする言語の名前です（french、 russian、japanese など）

言語ディレクトリには、通常のリアルタイムアプリケーション環境のファイルと同じファイルを格納 できます（つまり、特定の言語のアプリケーション環境を作成できます）。ただし、言語ディレクト リの中にさらに言語ディレクトリ（サブディレクトリ） を格納することはできません。

使用される言語は、リアルタイムアプリケーションのタスクを介して選択されます。デフォルト（英 語） 以外の言語が選択されている場合、アプリケーション上でリアルタイムアプリケーション環境の ファイルの読み取りが実行されると、選択されている言語の言語ディレクトリが使用されます。その 言語ディレクトリにファイルが見つからなかったときには、リアルタイムアプリケーション環境自体 からファイルが取り出されます（つまりデフォルトの言語ファイルが使用されます）。

CommuniGate Pro サーバーには、内蔵のリアルタイムアプリケーション環境が付属しています（「ス トック」リアルタイムアプリケーション環境とも呼びます）。この環境には、基本的なアプリケー ション（ と、そのアプリケーションの動作に必要なファイル） が格納されており、また、再利用可能 なコードセクションファイルとメディアファイルも格納されています。

CommuniGate Pro システムにはそれぞれ、サーバーワイドアプリケーション環境があります。ダイナミッククラスタ の場合、アプリケーション環境は、サーバーワイドではなく、クラスタワイドアプリ ケーション環境です。サーバーワイドまたはダイナミッククラスタの（ リアルタイム） アプリケー ション環境の設定や変更を行いたい場合、WebAdmin インターフェイスの［Domains］ セクションを 開き、［PBX］ リンクをクリックします。

また、CommuniGate Pro のドメイン にもそれぞれ、そのドメインのアプリケーション環境（ ドメイン アプリケーション環境） があります。ドメインアプリケーション環境の設定や変更を行いたい場合、 WebAdmin インターフェイスの［Domains］ セクションを開き、設定を行いたいドメインを選択しま す。その後、そのドメインの［Domain Settings］ ページを開き、［PBX］ リンクをクリックします。

クラスタワイドアプリケーション環境、または、共有ドメインのアプリケーション環境を変更した場 合、その変更は自動的にすべてのクラスタメンバーで有効になります。

上記のように、ドメインにはそれぞれ、そのドメイン独自のアプリケーション環境（ ドメインアプリ ケーション環境） があります。つまり、ドメインアプリケーション環境はそれぞれ独立しているた め、ドメインが異なればアプリケーションの名前は同じでもかまいません。

アプリケーション環境のファイルでは、非ASCII 文字のキャラクタセットはUTF-8 キャラクタセッ トでなければなりません。

リアルタイムアプリケーションのタスクは、CommuniGate Pro のアカウントの「資格」で実行されま す。
アプリケーションから何らかの環境ファイル（環境で使用されるファイル） が要求され、選択されて いる言語がデフォルトの言語（英語） の場合、CommuniGate Pro サーバー上で、次の場所（ディレク トリ） に対して検索が実行されます。そのファイルが見つかれば、そのファイルが使われます。

• アカウントが属するドメインの環境（ ドメイン環境）。
• サーバーワイド環境、またはクラスタワイド環境（アカウントが属しているドメインが共有ド メインの場合）。
• ストック（内蔵） 環境。

現在、選択されている言語がデフォルト以外の言語の場合、まず上記の3 つの環境の中の言語ディレ クトリの中に、そのファイルがあるかどうかがチェックされます。どの環境にもファイルがなかった ときには、上記の3 つの環境の中がチェックされます。つまり、デフォルト以外の言語のファイル （特定の言語のアプリケーション環境） が作成されていなかった場合、デフォルトの言語（英語） の ファイルが使用されます。

リアルタイムアプリケーション環境は上記のような階層構造になっているため、アプリケーションの カスタマイズは容易です。例えば、全ドメインの全アカウントで同じアプリケーションを使用できる ように設定できます（ この場合、ストック環境またはサーバーワイド環境を使用します）。また、ド メイン管理者は、そのドメインのドメイン環境のカスタマイズが可能です。カスタマイズするには、 そのドメイン環境にカスタムファイルをアップロードします。

リアルタイムアプリケーションは、タスクとして動作します。具体的には、リアルタイムアプリケー ションの起動の際、CommuniGate Pro サーバーによって新規のタスクが開始され、このタスクを介し て、そのアプリケーションのメインエントリコードセクション（entry Main） が実行されます。

リアルタイムアプリケーションのタスクは、非接続（disconnected） モードでの動作が可能です。ま た、ピア（peer） とのリアルタイムセッション（電話など） の一部として動作させることもできま す。ピアとは任意のリアルタイムエンティティをいい、例えば、SIP フォン、PSTN ゲートウエイ、 リモートのリアルタイムアプリケーション（SIP を介して通信を実行）、ローカルのリアルタイムア プリケーション（つまり他のタスク） はいずれもピアです。

ピアとタスクとの間でセッションが実行される場合、タスクの実行モードとしては状況によって次の 4 種類があります。

incoming

受信モード。受信セッション（電話用語ではコール/ 呼、SIP 用語ではINVITE 要求） がタスクに送られたが、タスクは、そのセッションをまだ受け取っていない状態。

provisioned

暫定応答（接続準備完了）モード。受信セッションがタスクに送られ、タスクは、そのセッションを まだ受け取っていないが、コーラー（発信側） に対して暫定応答が送信された状態。

connecting

接続中モード。タスクにより送信セッション（発信）が開始されたが、まだセッションが確立されて いない状態。

connected

接続完了モード。タスクで受信セッションが正常に受け取られた状態、または、タスクで送信セッ ションが確立された状態。

タスクは、ピアからシグナル を受信でき、またタスク自体からシグナルを送信することもできます。 シグナルを使ってカレントのセッションを終了させたり、セッションパラメータを更新したりできま す。ピアから送信されたシグナルの中には、リアルタイムアプリケーション環境で処理されるものも あります。これ以外のシグナルは、タスクに渡され処理されます。

リアルタイムアプリケーションのタスクには、メディアチャンネル（Media Channel） があります。 セッションが確立されると、メディアチャンネルがピアのメディアチャンネルと接続されます。

タスクでは、そのタスクのメディアチャンネルを使ってメディア（オーディオ、ビデオ） をピアに送 信できます。また、ピアから送られたメディアを保存することもできます。

タスクではまた、ピアで使用されているメディア（ピアのメディア） を別のメディアサービスに切り 替えることができます。例えば、ピアのメディアをミュージックオンホールド（保留音） （を提供す るサービス） などに切り替えることが可能です。ピアのメディアの切り替えが行われると、タスクの それまでのメディアチャンネルは使用できなくなります。ただし、タスクでは、シグナルをピアに送 信することでピアの制御が可能で、またピアからのシグナルの受信も可能です。その後、タスク側で 必要に応じて、以前のピアのメディアに再度、切り替えることができます。これで、タスクのメディ アチャンネル（以前のピアのメディアに使用されていたメディアチャンネル） も有効になります（下 記の図を参照）。

タスクのメディアチャンネルには、「カンバセーションスペース（会話空間）」があります。タスク は、カレントのピア以外のピアのメディアを、そのタスクのメディアチャンネルに接続できます。こ の処理により、カンバセーションスペース（カンファレンス） が作成されます。このスペースには、 タスクのカレントのピアと、ピアのメディアを介してタスクに接続されているピアが存在します。カ ンバセーションスペースに存在するいずれかのピアからメディアが送信された場合、そのメディアは 他のピアすべてにリレーされます。この場合の処理は、メディアのタイプに応じて、そのメディアの データミキシングアルゴリズムとパラメータを使って実行されます。

タスクにピアのメディアが接続されている場合、そのタスクから、そのタスクのピア（元々のピア） に加えて、接続されているピアに対して同時にメディアを送信できます。

コールトランスファー

上記のようにREFER 要求によってINVITE 要求処理が開始されますが、この場合、タスクでINVITE 要求（別のピアに送信） の認証情報のチェックが可能です。アプリケーションプログラム（のタス ク） では、次の処理が可能です。

• タスクの起動元のアカウントの認証情報を使ってINVITE シグナル（要求） の認証を行う。
• ピア（REFER 要求の送信元のエンティティ） の認証情報を使ってINVITE シグナルを認証する。
• INVITE シグナルを認証せずに送信する。

CommuniGate Pro にはコールトランスファー「補助」機能が用意されています。つまり、リアルタイ ムアプリケーションエンジンが搭載されており、このエンジンにより、INVITE シグナル（要求） の うちReplaces フィールドがあるINVITE シグナル（いずれかのピアから送信） が自動的に監視、検出 されます。ここで、Replaces フィールドに指定されているダイアログデータ（通話情報） が、いずれ かのタスクで確立されているアクティブダイアログデータと一致した場合、そのタスクにINVITE シ グナルが送られます。そのタスクでは、カレントのピアに対してBYE シグナルを送信します。同時 に、そのタスクのシグナルダイアログがINVITE シグナルのソース（ピア） に接続され、また、その タスクのメディアチャンネルが、そのINVITE シグナルに指定されているエンティティ（ピア） に切 り替わります（下図を参照）。
このコールトランスファー補助機能は自動的に実行され、タスクを実行しているアプリケーションプ ログラムには透過的です。

ブリッジドコール

• タスクA を実行するアプリケーションプログラムで、StartBridge 関数（CG/PL 関数） を使って特 殊イベント[bridgeStart] をタスクB に送信します。このイベント（要求） には、タスクA のカレントのピアのメディア識別情報が格納されています。
• タスクB を実行するアプリケーションプログラムで、この要求が受信されます。
• タスクB のアプリケーションプログラムで、AcceptBridge 関数（CG/PL 関数） を使って要求を受 け付けます（ブリッジが構築されます）。
• リアルタイムアプリケーションエンジンの指示により、タスクB から、そのピアに対してre- INVITE （再INVITE） シグナルが送信されます。タスクB のピアのメディアがタスクA のピア に送られるようになります（ メディアの送信先が切り替わります）。
• リアルタイムアプリケーションエンジンの指示により、特殊イベント[bridgeResponse] が タスクA に送信されます。このイベントには、タスクB のピアのメディア識別情報が格納され ています。
• タスクB のアプリケーションプログラムのAcceptBridge 処理が完了し、タスクB のアプリケー ションプログラムの処理が続行されます。
• タスクA で受信されたイベント[bridgeResponse] は、リアルタイムアプリケーションエンジ ンで処理されます。エンジンからタスクA のアプリケーションプログラムに渡されることはあ りません。
• リアルタイムアプリケーションエンジンの指示により、タスクA から、そのピアに対してre- INVITE （再INVITE） シグナルが送信されます。タスクA のピアのメディアが、タスクB のピ アに送られるようになります（ メディアの送信先が切り替わります）。
• タスクA のStartBridge 処理が完了し、タスクA のアプリケーションプログラムの処理が続行され ます。

タスクA とタスクB が「ブリッジ」で接続されている状態（ブリッジドコール） にある場合、どち らかのタスク（下の例ではタスクB） で、そのタスクのピアからre-INVITE シグナルを受信できま す。このre-INVITE シグナルに格納されているメディア識別情報を介して、そのタスクのメディアパ ラメータが変更されます（保留/ 再開の切り替え、別のメディアソースへの切り替えなど）。re- INVITE シグナルはリアルタイムアプリケーションエンジンによって自動的に処理され、したがって、 そのタスクのアプリケーションプログラムで処理を定義する必要はありません。

• リアルタイムアプリケーションエンジンの指示により、特殊イベント[bridgeUpdate] がタス クA に送信されます。このイベントには、新規のメディア識別情報（新規のメディアパラメー タ） が格納されています。
• リアルタイムアプリケーションエンジンによってイベント[bridgeUpdate] が処理されます。 したがって、このイベントはタスクA のアプリケーションプログラムには送信されません（プ ログラムで処理する必要はありません）。
• リアルタイムアプリケーションエンジンの指示により、re-INVITE シグナルがタスクA のピアに 送られます。これで、タスクA のピアがタスクB のピアの新規のメディアソースに接続されま す。
• リアルタイムアプリケーションエンジンによって、タスクA のピアの新規（変更後） のメディ ア識別情報（re-INVITE の応答に格納されている情報） がタスクB に送られます。この送信は、 特殊イベント[bridgeResponse] を使って行われます。
• タスクB で受信されたイベント[bridgeResponse] は、リアルタイムアプリケーションエンジ ン自体によって処理されます。このイベントはタスクB のアプリケーションプログラムには送 信されません（プログラムで処理する必要はありません）。
• タスクB から、タスクA のピアの新規（変更後） のメディア識別情報がタスクB のピアに送信さ れます。この情報は、最初のre-INVITE シグナル（ タスクA のピアから送信されたre-INVITE） の応答です。最後に、タスクB のピアがタスクA のピアの新規のメディアに接続され、その新 規のメディアを使って通信が実行されます。

タスクA とタスクB が「ブリッジ」で接続されている状態（ブリッジドコール） にある場合、どち らかのタスク（下の例ではタスクA） で、そのタスクのピアからコールトランスファー（REFER） シ グナルを受信できます。REFER シグナルの受信後、次のような処理が行われます。

• リアルタイムアプリケーションエンジンによってタスクA のINVITE シグナルが生成され、その INVITE シグナルがタスクA から参照先のピア（REFER シグナルで指定されているピア、下の 例ではピアC） に送信されます。このINVITE シグナルには、タスクB のピアのメディア識別 情報が格納されています。
• INVITE シグナル処理が成功すると、NOTIFY シグナルを介してタスクA の新規のピア（C） のメ ディア識別情報がタスクA に送信されます。
• リアルタイムアプリケーションエンジンによって、タスクA から自動的に特殊イベント [bridgeUpdate] がタスクB に送られます。このイベントには新規のピア（C） のメディア識 別情報が格納されています。
• タスクBで受信された特殊イベント[bridgeUpdate]はリアルタイムアプリケーションエンジ ン自体が処理します。したがって、タスクB のアプリケーションプログラムに送られることは ありません。
• リアルタイムアプリケーションエンジンの指示により、re-INVITE シグナルがタスクB のピアに 送信されます。これで、タスクB のピアがタスクA の新規のピア（C） の新規のメディアソー スに接続され、そのメディアソースを使って通信が実行されます。

タスクA とタスクB が「ブリッジ」で接続されている状態（ブリッジドコール） にある場合、一方 のタスク（ ここではタスクA） で、コールトランスファー（Replaces フィールド付きのINVITE） シ グナルを受信できます（ このシグナルは、Replaces フィールドの内容に応じてシグナル モジュールに よってタスクに送信されます）。受信後の処理は次の通りです。

• リアルタイムアプリケーションエンジンにより、タスクA から自動的に特殊イベント [bridgeUpdate] がタスクB に送られます。このイベントにはタスクA の新規のピアのメディ アパラメータが格納されています。
• リアルタイムアプリケーションエンジンの指示により、re-INVITE シグナルがタスクB のピアに 送信されます。これで、タスクB のピアがタスクA の新規のピアのメディアソースに接続され ます。
• リアルタイムアプリケーションエンジンの制御のもとで、INVITE シグナルがタスクA の新規の ピアに送信されます。このシグナルには、タスクB のメディアパラメータが格納されていま す。最後に、タスクA の新規のピアとタスクB のピアのメディアが接続されます。

また、タスクA とタスクB が「ブリッジ」で接続されている状態（ブリッジドコール） にある場合、 どちらかのタスク（下の例ではタスクA） でメディアブリッジを破棄できます。この場合の処理は次 の通りです。

• タスクA のアプリケーションプログラムで、BreakBridge 関数（CG/PL 関数） を使ってメディア ブリッジを破棄します。これで下記の処理が実行されます。
• リアルタイムアプリケーションエンジンにより、特殊イベント[bridgeClose] がタスクB に送 信されます。また、re-INVITE シグナルがタスクA のピアに送られます。この処理の結果、タ スクA のピアとタスクA のメディアチャンネルが接続されます（接続が切り替わります）。
• 特殊イベント[bridgeClose] がタスクB で受信されると、リアルタイムアプリケーションエン ジンが自動的にre-INVITE シグナルをタスクB のピアに送信します。その結果、タスクB のピ アとタスクB のメディアチャンネルが接続されます（接続が切り替わります）。
• 最後に、リアルタイムアプリケーションエンジンがイベント[bridgeClose] をタスクB のア プリケーションプログラムに送信します。

また、タスクA とタスクB が「ブリッジ」で接続されている状態（ブリッジドコール） にある場合、 一方のタスク（下の例ではタスクA） で、そのタスクのピアから切断（BYE） シグナルを受信できま す。このシグナルの受信により、タスクは終了します（ タスクは、これ以外の各種の理由でも終了し ます）。この場合の処理は次の通りです。

• ピアから切断（BYE） シグナルが受信されると、リアルタイムアプリケーションエンジンが自 動的にイベント[bridgeClose] をタスクB に送信します。
• 特殊イベント[bridgeClose] がタスクB で受信されると、リアルタイムアプリケーションエン ジンが自動的にre-INVITE シグナルをタスクB に送信します。その結果、タスクB のピアとタ スクB のメディアチャンネルが接続されます（接続が切り替わります）。
• 最後に、リアルタイムアプリケーションエンジンが特殊イベント[bridgeClose] をタスクB の アプリケーションプログラムに送信します。

場合によっては、リアルタイムアプリケーションエンジンにより、タスクのメディアチャンネルを 「メディアリレー」として使ってメディアブリッジが生成されることもあります。

B2BUA（バックツーバックユーザエージェント）

リアルタイムアプリケーションは、CG/PL 言語を使って作成できます。

受信コールの処理の際、タスクが生成されます。同時に、そのタスクのCG/PL アプリケーションプ ログラムのメインエントリ（entry Main） が実行されます。

リアルタイムアプリケーションでは、 外部宣言を使用できます。アプリケーションで外部宣言にコー ドセクション（プロシージャまたは関数） の名前を定義しておくと（キーワードexternal を使 用）、ファイル名が、そのコードセクションの名前で、かつ拡張子が.sppi のファイルがカレントの 環境から読み込まれます。この場合、そのファイルの中のプログラムコードには、外部宣言で指定し た名前のコードセクションが存在しなければなりません。また、コードセクションはプロシージャま たは関数でなければなりません。
そのファイル（.sppi） のプログラムコードには、外部宣言で呼び出すコードセクション以外のコー ドセクションも定義できます。

CG/PL 言語でリアルタイムアプリケーションを作成する場合、次の内蔵プロシージャ/ 関数を使用 できます。

入力

ReadInput(timeOut)

この関数では、外部タスクの通信データ、つまりピア上で入力されたDTMF 文字、ピアから送信さ れたシグナル、別のタスクやシステムから送信されたイベントを取得できます。イベントについて は、詳しくはCG/PL の「 イベント」のセクションを参照してください。
timeOutは数値で、ここには最大待機時間（ タイムアウト、単位秒） を指定します。timeOut の値を 0 にしておくと、タイムアウトなしでデータやイベントがチェック・取得されます。
この関数の戻り値は次の通りです。

• タスクのDTMF バッファの最初のDTMF 文字を格納した文字列。この文字は、タスクのDTMF バッファから削除されます。
• 最初のイベント （キューで待機中の最初のイベント） を格納した辞書。このイベントは、タス クのイベントキューから削除されます。
• 指定した待機時間（ timeOut） 内にDTMF 文字またはイベントが取得されなかったときには NULL 値が返ります。

ピアとの接続が切断された場合、タスクはシステムから切断イベント（Disconnect Event）を受け取 ります（このイベントの辞書には、.sender 要素は格納されていません）

IsDisconnectEvent(input)

inputの値が切断イベント（Disconnect Event）の場合、この関数からTRUE 値が返ります。

//
// Sample: ReadInput()
//   Accept an incoming call (stop if it's not possible).
//   Play the PressPound media file.
//   Wait for any input for up to 5 seconds.
//   If the "pound" ("#") symbol was entered,
//     play the Good media file.
//   Otherwise,
//     play the Bad media file.
//   Stop.
//
entry Main is
  if AcceptCall() != null then stop; end if;
  PlayFile("PressPound");
  PlayFile(ReadInput(5) == "#" ? "Good" : "Bad");
end entry;

シグナル

RejectCall(responseCode)

このプロシージャでは、受信セッション（INVITE 要求） が存在する場合、その受信セッションの拒 否が可能です。タスクのモードは、incoming またはprovisioned のいずれかでなければなりま せん。
responseCode （数値） には400 から699 までのいずれかの数値を指定します。この数値が、コーラー にシグナル応答コードとして返却されます。401 を指定しておいた場合、要求がCommuniGate Pro サーバーの外部から送信された（SIP プロトコル経由） 要求だったときには、SIP サーバーモジュー ルにより所定のフィールドが応答に追加されます。追加されたフィールドは、クライアント認証に利 用可能です。
タスクのモードはdisconnected に変更されます。

AcceptCall()

この関数を使って、受信セッションが存在する場合、その受信セッションを受け取る（処理する）こ とができます。タスクのモードは、incoming またはprovisioned のいずれかでなければなりま せん。
受信セッションの受け取りに成功した場合、この関数からNULL 値が返ります。同時に、タスクの モードがconnected に変更されます。
受信セッションの受け取りに失敗したときには、エラーコード文字列が返ります。また、タスクの モードがdisconnected に設定されます。

//
// Sample: AcceptCall()/RejectCall()
//   If the current local time is not between 8:00 and 17:00,
//     reject the call (with the 403 error code) and stop.
//   Otherwise,
//     accept the call (stop if it is not possible)
//     play the Welcome media file and stop.
//
entry Main is
  currentTime = TimeOfDay(GMTToLocal(GMTTime()));
  currentHour = currentTime / 3600;
  if currentHour < 8 or currentHour >= 17 then
    RejectCall(403); stop;
  end if;
  if AcceptCall() != null then stop; end if;
  PlayFile("Welcome");
end entry;

RedirectCall(newURI)

このプロシージャでは、受信セッションが存在する場合、その受信セッションのリダイレクトが可能 です。タスクのモードは、incoming またはprovisioned のいずれかでなければなりません。
newURIの値は、文字列または文字列の配列のいずれかでなければなりません。newURIで指定した URL に受信セッションがリダイレクトされます。タスクのモードは、disconnected に切り替わりま す。

ForkCall(newURI)

このプロシージャでは、受信セッションが存在する場合、その受信セッションのリダイレクト （フォーク）が可能です。タスクのモードは、incoming またはprovisioned のいずれかでなければなり ません。
newURIの値は、文字列または文字列の配列のいずれかでなければなりません。newURIで指定した URL に受信セッションがリダイレクトされます。カレントのタスクのモードは、そのまま維持され ます。したがって、その後、このコールの受け取り、拒否、暫定応答、リダイレクト、フォークが可 能です。

ProvisionCall(startMedia,reliably)

この関数を使用して、待機中の受信セッション要求が存在する場合、その要求に対して暫定応答を送 信できます。タスクのモードは、incoming またはprovisioned のいずれかでなければなりませ ん。
startMedia （ メディアチャンネル開始） の値がNULL 値でない（TRUE を指定した） 場合、タスクの メディアチャンネルが生成され、タスクのモードがprovisioned に設定されます。また、メディ アチャンネル処理（PlayFile など） を使って「呼び返し音（ring-back tone）」を生成できる状態に なります。
reliablyの値がNULL 値でない（TRUE を指定した） 場合、暫定応答の確認要求（SIP のPRACK） が送 信されます。その後、タスクは、確認要求の応答が返るまで待機状態を維持します。
暫定応答が正常に送信された場合、この関数からはNULL 値が返ります。暫定応答の送信に失敗し たときには、この関数からエラーコード文字列が返ります。

//
// Sample: RedirectCall()/ProvisionCall()
//   Provision the call (stop if it is not possible).
//   If the current local time is between 12:00 and 13:00,
//     fork the call to user1 in the same domain.
//   Play the "PleaseWait" media file.
//   If the current local time is not between 8:00 and 17:00,
//     redirect the call to user2 in the same domain, and stop.
//   Otherwise,
//   Accept the call (stop if it's not possible).
//   Play the Welcome media file, and stop.
//
entry Main is
  if ProvisionCall(true,true) != null then stop; end if;
  currentTime = TimeOfDay(GMTToLocal(GMTTime()));
  currentHour = currentTime / 3600;
  if currentHour >= 12 and currentHour <= 13 then
    ForkCall("sip:user1@" + MyDomain());
    stop;
  end if;
  PlayFile("PleaseWait");
  if currentHour < 8 or currentHour >= 17 then
    RedirectCall("sip:user2@" + MyDomain());
    stop;
  end if;
  if AcceptCall() != null then stop; end if;
  PlayFile("Welcome");
end entry;

注意: 何らかの理由で待機中の受信コールの処理がキャンセルされた場合、タスクには切断イベント （Disconnect Event） が送られます。この切断イベントがタスクで受信されると、タスクのモードが disconnected に切り替わります。

StartCall(destination)

この関数を使って、送信セッション（送信コール/ 発信） を開始できます。タスクのモードは、 disconnected でなければなりません。
sendURI の値は文字列でなければなりません。このパラメータには、セッション要求の送信先のURI を指定します。または、下記の要素を格納した辞書を指定します。

"" （キー名が空白の文字列の要素）

要求の送信先のURI。

From （オプション）

URI。要求のFrom フィールドに格納されます。

To （オプション）

an E-mail, URI, or field-data to use for the request To field. If not specified, the request URI is used.

Call-ID （オプション）

コールID を示す文字列。要求のCall-ID フィールドに格納されます。

Expires （オプション）

a number specifying the maximum calling (alerting) time (in seconds).

Subject （オプション）

request Subject string.

Remote-Party-Id （オプション）

リモートパーティID を示す辞書。この辞書は要求のRemote-Party-Id フィールドに格納されます。

Privacy （オプション）

a string to use for the request Privacy field.

Diversion （オプション）

an array to use for the request Diversion fields.

P-CGP-Private （オプション）

a string to use for the request P-CGP-Private field. This field can be used to pass arbitrary parameters between sending and receiving Tasks (on the same or different systems).

送信セッション（発信） の開始に失敗したときには、この関数からエラーコード文字列が返ります。
送信セッションが正常に開始されたときには、関数からNULL 値が返ります。その後、システムか らコールプログレス（進行状況） イベントがタスクに送られ、タスクで受信されます。この場合、ま ず暫定応答（provisional response） イベント（0 個以上） が、その後、最終応答（final response） イベ ント（1 つ） が受信されます。
送信セッションの確立に成功したときには、パラメータなしの最終応答が受信されます。送信セッ ションの確立に失敗したときには、パラメータが1 つ（エラーコード文字列） の最終応答が受信され ます。

IsCallProvisionEvent(input)

inputの値が暫定応答（provisional response） イベントだった場合、この関数からTRUE 値が返りま す。それ以外の場合、NULL 値が返ります。

IsCallCompletedEvent(input)

inputの値が最終応答（final response） イベントだった場合、この関数からTRUE 値が返ります。それ 以外の場合、NULL 値が返ります。タスクで、パラメータなしの最終応答イベントが受信された場 合、コールシグナリング処理が正常に完了したことを示します。一方、受信された最終応答イベント にパラメータ（エラーコード文字列） が存在した場合、コール処理が失敗したことを意味します。

CancelCall()

タスクに待機中の送信セッション（StartCall 関数によって開始された送信セッション） がある場合、 このプロシージャを使って、その送信セッションをキャンセルできます。キャンセルしたときには、 タスクでは最終応答イベントは受信されません。

Disconnect()

このプロシージャでは、アクティブのセッションを終了できます。タスクのモードは、disconnected に切り替わります。

//
// Sample: StartCall()/Disconnect()
//   Accept an incoming call (stop if it's not possible).
//   Remember the caller URI.
//   Play the CallBack media file.
//   Disconnect();
//   Call the caller back (stop if it's not possible).
//   Play the IamBack media file, and stop.
//
entry Main is
  if AcceptCall() != null then stop; end if;
  fromWhom = RemoteURI();
  PlayFile("CallBack");
  Disconnect();

  if StartCall(fromWhom) != null then stop; end if;

  loop
    input = ReadInput(3600);
  exitif not IsCallProvisionEvent(input);
    null;
  end loop;

  if not IsCallCompletedEvent(input) or else
     input.parameter != null then stop; end if;

  PlayFile("IamBack");
end entry;

IsConnected()

タスクのモードがconnected だった場合、この関数からTRUE 値が返ります。

IsHalfConnected()

タスクのモードがconnected またはprovisioned だった場合、この関数からTRUE 値が返ります。

PendingRequestData(fieldName)

この関数では、待機中の受信要求のデータ要素を取り出すことができます。
処理対象の要求がなかったときは、この関数からNULL 値が返ります。待機中の要求があった場合、 fieldName （文字列） に指定した要素（フィールド） に応じて、その要素の値が返ります。fieldName に指定できるフィールドは次の通りです。

Call-ID

要求のCall-ID （ コールID） の値が返ります。値は文字列です。

From, To, Remote-Party-Id

指定したフィールド（上記のいずれか）が要求に存在した場合、辞書が返ります。この辞書の要素は 次の通りです。

"" （キー名が空白の文字列の要素）

アドレス（ username@domainの形式）。

@realName

アドレスの「表示名（実名）」の部分の文字列。

tag

URI の"tag" パラメータ。

@uri-params

他の各URI パラメータを格納した辞書。

上記の要素は、アドレス（""）を除きすべてオプションです。

Route, Record-Route, Diversion, Via, Path, Supported, Require, Proxy-Require, Privacy

フィールドの値を格納した文字列（単一もしくは複数） の配列が返ります。フィールドの値が存在し なかった場合、NULL 値が返ります。

CSeq

CSeq フィールドの数値の部分の値（数値） が返ります。

Max-Forwards

CSeq フィールドの値（数値） が返ります。

User-Agent, Reason, Privacy, P-CGP-Private

フィールドの値を格納した文字列が返ります。フィールドが存在しなかった場合、NULL 値が返りま す。

Accept

配列が返ります。配列には2 つの文字列、つまり有効と認められたコンテントタイプを示す文字列と 有効と認められたコンテントサブタイプを示す文字列が格納されています。このフィールドが存在し なかった場合、NULL 値が返ります。

Foreign-Asserted-Identity

the function returns an array containing one dictionary for each request P-Asserted-Identity field. Each dictionary contains the same elements as the From field dictionary.

If no request is pending, the function returns a null-value.

SetForeignCredentials(authName,password)

このプロシージャでは、資格情報（正規の名前とパスワード） をできます。ここで指定した資格情報 が、このタスクを使って送信される送信要求に使用されます。authName （正規の名前） とpassword （パスワード） は文字列でなければなりません。そうでない場合、資格情報はリセットされます。

SetReferMode(mode)

タスクでは、REFER要求で開始されるINVITE要求の認証が可能ですが、このプロシージャを使っ て、その方法を指定できます。方法は、パラメータmode （文字列） に指定します。指定できる値 は、次のいずれかです。

self

タスクの起動元のアカウント（カレントのアカウント） の認証情報を使って、INVITE 要求が認証さ れます。

peer

タスクのピア（REFER 要求の送信元） の認証情報を使って、INVITE 要求が認証されます。

上記以外の値

REFER 要求の処理（認証） は行われません。

SetTransferReportMode(mode)

This function sets the function flag for call transfer reporting.
If the mode value is a null-value, no event is sent when a Task is transferred to a different peer.
Otherwise, the Task receives a special CallTransferred Event when it is tarnsferred to a different peer.
The function returns the previous value of this function flag.
When a new Task is created, its call transfer reporting is disabled (the function flag is set to a null-value).

IsCallTransferredEvent(input)

This function returns a true-value if the input value is a CallTransferred Event. Otherwise the function returns a null-value.

SetBridgeBreakMode(mode)

このプロシージャでは、別のタスクによってメディアブリッジが破壊された場合のタスクの応答処理 を指定できます。処理は、パラメータmode に指定します。mode の値は文字列でなければなりませ ん。

disconnect

この値を指定しておいた場合、BYE シグナルがタスクのピアに送られ、同時にタスクのモードが disconnectedに切り替わります。

keep

タスクにメディアチャンネルがなかった場合、メディアチャンネルが作成されます。そのメディア チャンネルにタスクのピアが接続されます。

ダイアログ

RemoteURI()

この関数からは、ピア（ リモート） のURI （ダイアログのFrom/To アドレスから取得） を格納した 文字列が返ります。セッションが存在しない場合、この関数からはNULL 値が返ります。

LocalURI()

この関数からは、タスク（ ローカル） のURI を格納した文字列が返ります。

IncomingRequestURI()

この関数は、待機中の受信INVITE 要求のURI を格納した文字列を返します。待機中の受信INVITE 要求がない場合、NULL 値が返ります。

RouteLocalURI(uri)

この関数では、URL を指定し、そのURI に格納されている電子メールアドレスをルート できます。 URI の解析に失敗した場合、またはアドレスをルートできなかった場合、もしくはルート先が非ロー カルアドレス（つまり、別のシステムでホストされているアドレス） だったときには、この関数から NULL 値が返ります。それ以外の場合、この関数からはCommuniGate Pro ユーザーの電子メールアド レス（URI のアドレスのルート先のアドレス） が返ります。
この関数では、フォワーダや エイリアスなどを含め、CommuniGate Pro のルーティングメソッドでサ ポートされているアドレスもすべて正常に処理されます。

RemoteIPAddress()

この関数は、セッション確立要求の受信元または送信先のIP アドレス（ リモートIP アドレス） が返 ります。

RemoteAuthentication()

セッション開始要求が認証されなかった場合、この関数からはNULL 値が返ります。認証に成功し た場合、認証済みのユーザーの電子メールアドレスが返ります。

DTMF

//
// Sample: ReadInput()/SendDTMF()
//   Accept an incoming call (stop if it's not possible).
//   Wait for an input for 10 seconds. If no input - stop.
//   If a digit is entered
//      play that digit, and send it back.
//      (using "0" ... "9" files)
//   If a star ("*") is entered,
//     wait for a digit (for 3 seconds)
//     and play the digit number square (2 digits)
//   If a pound ("#") is entered or the Peer
//     has disconnected, or any Event was sent, stop.
//
entry Main is
  if AcceptCall() != null then stop; end if;
  loop
    input = ReadInput(10);
	if input == "*" then
	  input = ReadInput(3);
	  if IsString(input) and input != "#" then
	    input = "*" + input;
	  end if;
	end if;
  exitif not IsString(input) or input == "#";
    if Substring(input,0,1) != "*" then
	  PlayFile(input);
	  void(SendDTMF(input));
	else
	  input = Number(Substring(input,1,1);
	  product = input *  input;
	  PlayFile(String(product/10));
	  PlayFile(String(product%10));
	end if;
  end loop;
end entry;

メディア

PlayFile(fileName)

このプロシージャを使って、アプリケーション環境からファイルを取り出し、そのファイルを実行 （再生） できます。文字列パラメータfileNameには、そのファイルのファイル名を指定します。指定したファイルにファイル拡張子がなかった場合、サポートされている拡張子が自動的に追加されます。
ファイルは、サポートされているフォーマットのいずれかで、またメディアデータが格納されていな ければなりません。
セッションが終了した場合、DTMF バッファが空でない場合、このタスクのイベントがキューされて いる場合、ファイルは実行されないか、処理が中断されます。

PlayFileInLoop(fileName,msec)

このプロシージャは、PlayFile プロシージャと基本的には同じです。パラメータmsec の値は、数 値でなければなりません。
このプロシージャでは、fileNameに指定したファイルをmsecで指定した時間の長さ（ ミリ秒） だけ 再生できます。ファイルのメディア再生時間長がmsecで指定した時間長より短い場合、ファイルは 繰り返し再生されます。msecに負の値を指定しておくと、時間の制限なしにファイルが繰り返し再 生されます。
セッションが終了した場合、DTMF バッファが空でない場合、このタスクのイベントがキューされて いる場合、ファイルは実行されないか、処理が中断されます。

Play(waveData)

このプロシージャでは、waveDataにデータブロック（波形データ） を指定し、そのデータブロック を再生できます。データブロックのデータ（ メディアデータ） のフォーマットは、サポートされてい るフォーマットのいずれかでなければなりません。
セッションが終了した場合、DTMF バッファが空でない場合、このタスクのイベントがキューされて いる場合、ファイルは実行されないか、処理が中断されます。

PlayInLoop(waveData,msec)

このプロシージャは、基本的にはPlay プロシージャと同じです。ただし、メディアデータをループ で再生できます。このループ処理は、PlayFileInLoop プロシージャの場合と同じです。

Record(timeLimit)

この関数を使って、受信音声データを記録できます。timeLimitは正の数値でなければなりません。 timeLimitには最大記録時間長（秒） を指定します。セッションが終了した場合、DTMF バッファが 空でない場合、このタスクのイベントがキューされている場合、ファイルは実行されないか、処理が中断されます。
受信音声データの記録に失敗したときにはNULL 値が返ります。成功したときには、記録されたサ ウンドを格納したデータブロック（WAV フォーマット） が返ります。

SetLocalHold(flag)

This procedure sets the current call "on Hold" (if the flag is a true-value), or releases the call from hold (if the flag is a null-value).
This procedure can be used only when the Task is in the connected mode, and the Task peer media is not bridged.

ReleaseMediaChannel()

This procedure releases the Task Media Channel (releasing the associated system resources).
This procedure can be used only when the Task is in the disconnected mode, or when the Task peer media is bridged.

//
// Sample: Record()/PlayFile()/Play()
//   Accept an incoming call (stop if it's not possible).
//   Play the GreetingIs file.
//   Read the current prompt from
//      the MyGreeting.wav file in the Personal Site.
//   Loop playing the greeting.
//      if "1" is entered, rewrite the prompt file and quit
//      if "2" is entered, play "Beep" and record the prompt.
//
entry Main is
  if AcceptCall() != null then stop; end if;
  PlayFile("GreetingIs");
  prompt = ReadSiteFile("MyGreeting.wav");
  loop
    if IsData(prompt) then Play(prompt); end if;
    input = ReadInput(10);
  exitif not IsString(input) or else input == "#";
    if input == "1" then
	  if WriteSiteFile("MyGreeting.wav",prompt) then
	    PlayFile("Goodbye"); stop;
	  end if;
	  PlayFile("Failure");
	elif input == "2" then
	  PlayFile("Beep");
	  prompt = Record(30);
	else
	  PlayFile("InvalidEntry");
	end if;
  end loop;
  PlayFile("GoodBye");
end entry;

Bridges and Mixers

//
// Sample: StartBridge()/AcceptBridge()/BreakBridge()
//   Accept an incoming call (stop if it's not possible).
//   Create a new Task to run the Caller code,
//     and send it an Event with the URI to dial.
//   Play the PleaseWait media file.
//   Wait for a StartBridge Event from the Caller Task.
//   Accept it and loop till the user disconnects.
//
//   The Caller code:
//   Receive a URI to call as an Event from the parent Task
//   Connect to the URI and play the YouGotACall media file
//   StartBridge with the parent, loop till the user disconnects
//
entry Caller forward;
procedure ControlBridge() forward;

entry Main is
  if AcceptCall() != null then stop; end if;

  callerTask = spawn Caller;
  if callerTask == null or else
     SendEvent(callerTask,"dial","sip:internal@partner.dom") != null then
	PlayFile("Failure");
	stop;
  end if;

  PlayFile("PleaseWait");
  input = ReadInput(30);
  if not IsStartBridgeEvent(input) or else
     AcceptBridge(input) != null then
	PlayFile("Failure");
	stop;
  end if;

  // we have established a bridge
  ControlBridge();
  PlayFile("GoodBye");
end entry;

//
// Caller Task code
//
entry Caller is
  // wait for a "dial" event from the main task
  input = ReadInput(30);
  if input == null or input.what != "dial" then stop; end if;

  mainTask = input.sender;

  // Calling the URI specified as the Event parameter
  // If connection failed, send an Event back to the
  //  main task and quit 
  resultCode = StartCall(startEvent.parameter);
  if resultCode != null then
    void(SendEvent(mainTask,"result",resultCode));
	stop;
  end if;

  // wait for any Event other than provisional ones
  loop
    input = ReadInput(3600);
  exitif not IsCallProvisionEvent(input);
  end loop;

  // the parent has sent us "stop" - then we'll die immediately
  if IsDictionary(input) and then input.what == "stop" then stop; end if;
  
  if not IsCallCompletedEvent(input) or else input.parameter != null then
    void(SendEvent(mainTask,"result","generic error"));
	stop;
  end if;

  if StartBridge(mainTask) != null then
	PlayFile("Failure");
	stop;
  end if;

  // we have established a bridge
  ControlBridge();
  PlayFile("GoodBye");
end entry;

//
// Controlling the peer signaling:
// while the media is bridged:
//	exit if the peer hangs up, dials "#"
//  or if the bridge is removed
//  
procedure ControlBridge() is
  loop
    input = ReadInput(3600);
  exitif IsBreakBridgeEvent(input) or else 
          IsDisconnectEvent(input) or else input == "#";
  end loop;
  void(BreakBridge());
end procedure;

Call Transfer

Info Requests